Pod::Simple::Wiki::Confluence - A class for creating Pod to Confluence wiki filters.

Pod-Simple-Wiki documentation Contained in the Pod-Simple-Wiki distribution.

Index

Code Index:

NAME

Top

Pod::Simple::Wiki::Confluence - A class for creating Pod to Confluence wiki filters.

SYNOPSIS

Top

This module isn't used directly. Instead it is called via Pod::Simple::Wiki:

    #!/usr/bin/perl -w

    use strict;
    use Pod::Simple::Wiki;




    my $parser = Pod::Simple::Wiki->new('confluence');

    ...

Convert Pod to a Confluence wiki format using the installed pod2wiki utility:

    pod2wiki --style confluence file.pod > file.wiki

DESCRIPTION

Top

The Pod::Simple::Wiki::Confluence module is used for converting Pod text to Wiki text.

Pod (Plain Old Documentation) is a simple markup language used for writing Perl documentation.

For an introduction to Confluence see: http://www.atlassian.com/software/confluence/

This module isn't generally invoked directly. Instead it is called via Pod::Simple::Wiki. See the Pod::Simple::Wiki and pod2wiki documentation for more information.

METHODS

Top

Pod::Simple::Wiki::Confluence inherits all of the methods of Pod::Simple and Pod::Simple::Wiki. See Pod::Simple and Pod::Simple::Wiki for more details.

SEE ALSO

Top

This module also installs a pod2wiki command line utility. See pod2wiki --help for details.

ACKNOWLEDGEMENTS

Top

Thanks to David Bartle, Andrew Hobbs and Jim Renwick for patches.

DISCLAIMER OF WARRANTY

Top

Please refer to the DISCLAIMER OF WARRANTY in Pod::Simple::Wiki.

AUTHORS

Top

John McNamara jmcnamara@cpan.org

COPYRIGHT

Top

© MMIII-MMVIII, John McNamara.

All Rights Reserved. This module is free software. It may be used, redistributed and/or modified under the same terms as Perl itself.

Pod-Simple-Wiki documentation Contained in the Pod-Simple-Wiki distribution. 
package Pod::Simple::Wiki::Confluence;

###############################################################################
#
# Pod::Simple::Wiki::Confluence - A class for creating Pod to Confluence filters.
#
#
# Copyright 2003-2008, John McNamara, jmcnamara@cpan.org
#
# Documentation after __END__
#

use Pod::Simple::Wiki;
use strict;
use vars qw(@ISA $VERSION);


@ISA     = qw(Pod::Simple::Wiki);
$VERSION = '0.09';

###############################################################################
#
# The tag to wiki mappings.
#
my $tags = {
            '<b>'    => '*',
            '</b>'   => '*',
            '<i>'    => '_',
            '</i>'   => '_',
            '<tt>'   => '{{',
            '</tt>'  => '}}',
            '<pre>'  => "{noformat}\n",
            '</pre>' => "\n{noformat}\n",

            '<h1>'   => 'h1. ',
            '</h1>'  => "\n\n",
            '<h2>'   => 'h2. ',
            '</h2>'  => "\n\n",
            '<h3>'   => 'h3. ',
            '</h3>'  => "\n\n",
            '<h4>'   => 'h4. ',
            '</h4>'  => "\n\n",
           };

###############################################################################
#
# new()
#
# Simple constructor inheriting from Pod::Simple::Wiki.
#
sub new {

    my $class                   = shift;
    my $self                    = Pod::Simple::Wiki->new('wiki', @_);
       $self->{_tags}           = $tags;

    bless  $self, $class;
    return $self;
}

###############################################################################
#
# _indent_item()
#
# Indents an "over-item" to the correct level.
#
sub _indent_item {

    my $self         = shift;
    my $item_type    = $_[0];
    my $item_param   = $_[1];
    my $indent_level = $self->{_item_indent};

    if    ($item_type eq 'bullet') {
         $self->_append('*' x $indent_level . ' ');
    }
    elsif ($item_type eq 'number') {
         $self->_append('#' x $indent_level . ' ');
    }
    # Confluence doesn't have the equivalent of a <dl> list so we use a
    # bullet list with a bolded "item" as a workaround.
    elsif ($item_type eq 'text') {
         $self->_append('*' x $indent_level . ' *');
    }
}

###############################################################################
#
# _handle_text()
#
# Perform any necessary transforms on the text. This is mainly used to escape
# inadvertent CamelCase words.
#
sub _handle_text {

    my $self = shift;
    my $text = $_[0];

    # Only escape words in paragraphs
    if (not $self->{_in_Para}) {
        $self->{_wiki_text} .= $text;
        return;
    }

    # Split the text into tokens but maintain the whitespace
    my @tokens = split /(\s+)/, $text;

    # Escape any tokens here, if necessary.

    # Rejoin the tokens and whitespace.
    $self->{_wiki_text} .= join '', @tokens;
}


###############################################################################
#
# Functions to deal with =over ... =back regions for
#
# Bulleted lists
# Numbered lists
# Text     lists
# Block    lists
#
sub _end_item_text     {$_[0]->_output('* ')}


###############################################################################
#
# _start_Para()
#
# Special handling for paragraphs that are part of an "over" block.
#
sub _start_Para {

    my $self         = shift;
    my $indent_level = $self->{_item_indent};

    if ($self->{_in_over_block}) {
        $self->_append('bq. ');
    }
}


1;


__END__