QualysGuard::Response - subclass of XML::XPath used to handle QualysGuard API XML responses

    use QualysGuard::Request;

    $QualysGuard::Request::Username = "username";
    $QualysGuard::Request::Password = "password";

    my $qualys_request = QualysGuard::Request->new( 'map_report_list' );

    # - provide map_report_list function arguments

    $qualys_request->attributes({
        'last'    => 'yes',
        'domain'  => 'example.com', 
    });

    my $qualys_response = $qualys_request->submit();

    if ( $qualys_response->is_error() ) {
        die $qualys_response->get_error(); 
    }

    $qualys_response->save_to( 'map_report_list.xml' );

    ...

    perldoc QualysGuard::Request

package QualysGuard::Response;

use warnings;
use strict;

use base qw( XML::XPath );
use IO::File;
use Carp;

our $VERSION = '0.02';



# -------------------------------------------------------------------
#   new - constructor
# -------------------------------------------------------------------
sub new {
    my ( $class, $xml ) = @_;

    if ( ! defined $xml ) {
        croak "Missing or undefined XML response";
    }

    my $self = __PACKAGE__->SUPER::new( $xml );

    # -- extract the DOCTYPE
    my $doctype = (split("\n", $xml))[1];

    if ( $doctype !~ m/^<!DOCTYPE\ (.*)\ SYSTEM "(.[^"]*)">/ ) {
        croak "Missing on unknown DOCTYPE";
    }

    $self->{doctype}    = $1;
    $self->{dtd}        = $2;
    $self->{data}       = undef;
    $self->{xsl_output} = undef;
    $self->{error_code} = undef;
    $self->{error_text} = undef;

    return $self;
}


# -------------------------------------------------------------------
#   is_error
# -------------------------------------------------------------------
sub is_error {
    my $self = shift;
    return ( defined $self->{error_code} ) ? 1 : 0;
}



# -------------------------------------------------------------------
#   error_code
# -------------------------------------------------------------------
sub error_code {
    my $self = shift;
    if ( $self->is_error() ) {
        return $self->{error_code};
    }
}



# -------------------------------------------------------------------
#   get_error
# -------------------------------------------------------------------
sub get_error {
    my $self = shift;
    if ( $self->is_error() ) {
        return sprintf("Qualys Error [%s] : %s", $self->{error_code}, $self->{error_text} );
    }
}



# -------------------------------------------------------------------
#   save_to
# -------------------------------------------------------------------
sub save_to {
    my $self = shift;
    my $filename = shift;
    my $FH = IO::File->new();

    if ( $FH->open("> $filename") ) {
        print $FH $self->get_xml();
        $FH->close();
    }

    else {
        carp "Error : $!";
    }
}



1;

__END__