RDF::Trine::Serializer::NQuads - N-Quads Serializer

RDF-Trine documentation Contained in the RDF-Trine distribution.

Index

Code Index:

NAME

Top

RDF::Trine::Serializer::NQuads - N-Quads Serializer

VERSION

Top

This document describes RDF::Trine::Serializer::NQuads version 0.135

SYNOPSIS

Top

 use RDF::Trine::Serializer::NQuads;
 my $serializer	= RDF::Trine::Serializer::NQuads->new();

DESCRIPTION

Top

The RDF::Trine::Serializer::NQuads class provides an API for serializing RDF graphs to the N-Quads syntax.

METHODS

Top

Beyond the methods documented below, this class inherits methods from the RDF::Trine::Serializer class.

new

Returns a new N-Quads serializer object.

serialize_model_to_file ( $fh, $model )

Serializes the $model to N-Quads, printing the results to the supplied filehandle <$fh>.

serialize_model_to_string ( $model )

Serializes the $model to N-Quads, returning the result as a string.

serialize_iterator_to_file ( $file, $iter )

Serializes the iterator to N-Quads, printing the results to the supplied filehandle <$fh>.

serialize_iterator_to_string ( $iter )

Serializes the iterator to N-Quads, returning the result as a string.

SEE ALSO

Top

http://sw.deri.org/2008/07/n-quads/

AUTHOR

Top

Gregory Todd Williams <gwilliams@cpan.org>

COPYRIGHT

Top

Copyright (c) 2006-2010 Gregory Todd Williams. This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

RDF-Trine documentation Contained in the RDF-Trine distribution. 
# RDF::Trine::Serializer::NQuads
# -----------------------------------------------------------------------------


package RDF::Trine::Serializer::NQuads;

use strict;
use warnings;
use base qw(RDF::Trine::Serializer);

use URI;
use Carp;
use Data::Dumper;
use Scalar::Util qw(blessed);

use RDF::Trine::Node;
use RDF::Trine::Statement;
use RDF::Trine::Error qw(:try);

######################################################################

our ($VERSION);
BEGIN {
	$VERSION	= '0.135';
	$RDF::Trine::Serializer::serializer_names{ 'nquads' }	= __PACKAGE__;
	$RDF::Trine::Serializer::format_uris{ 'http://sw.deri.org/2008/07/n-quads/#n-quads' }	= __PACKAGE__;
	foreach my $type (qw(text/x-nquads)) {
		$RDF::Trine::Serializer::media_types{ $type }	= __PACKAGE__;
	}
}

######################################################################


sub new {
	my $class	= shift;
	my %args	= @_;
	my $self = bless( {}, $class);
	return $self;
}


sub serialize_model_to_file {
	my $self	= shift;
	my $file	= shift;
	my $model	= shift;
	my $iter	= $model->as_stream;
	while (my $st = $iter->next) {
		print {$file} $self->_statement_as_string( $st );
	}
}


sub serialize_model_to_string {
	my $self	= shift;
	my $model	= shift;
	my $iter	= $model->as_stream;
	my $string	= '';
	while (my $st = $iter->next) {
		my @nodes	= $st->nodes;
		$string		.= $self->_statement_as_string( $st );
	}
	return $string;
}


sub serialize_iterator_to_file {
	my $self	= shift;
	my $file	= shift;
	my $iter	= shift;
	while (my $st = $iter->next) {
		print {$file} $self->_statement_as_string( $st );
	}
}


sub serialize_iterator_to_string {
	my $self	= shift;
	my $iter	= shift;
	my $string	= '';
	while (my $st = $iter->next) {
		my @nodes	= $st->nodes;
		$string		.= $self->_statement_as_string( $st );
	}
	return $string;
}

sub _serialize_bounded_description {
	my $self	= shift;
	my $model	= shift;
	my $node	= shift;
	my $seen	= shift || {};
	return '' if ($seen->{ $node->sse }++);
	my $iter	= $model->get_statements( $node, undef, undef );
	my $string	= '';
	while (my $st = $iter->next) {
		my @nodes	= $st->nodes;
		$string		.= $self->_statement_as_string( $st );
		if ($nodes[2]->isa('RDF::Trine::Node::Blank')) {
			$string	.= $self->_serialize_bounded_description( $model, $nodes[2], $seen );
		}
	}
	return $string;
}

sub _statement_as_string {
	my $self	= shift;
	my $st		= shift;
	my @nodes;
	if ($st->type eq 'TRIPLE') {
		@nodes	= $st->nodes;
	} else {
		my $g	= $st->context;
		if ($g->is_nil) {
			@nodes	= ($st->nodes)[0..2];
		} else {
			@nodes	= $st->nodes;
		}
	}
	return join(' ', map { $_->as_ntriples } @nodes) . " .\n";
}


1;

__END__