RT::Extension::Converter::RT1 - Handle the RT1 side of a conversion

    use RT::Extension::Converter::RT1;
    my $converter = RT::Extension::Converter::RT1->new;

 _run_query( sql => $sql, placeholders => \@placeholders )

package RT::Extension::Converter::RT1;

use warnings;
use strict;
use base qw(Class::Accessor::Fast);
__PACKAGE__->mk_accessors(qw(config _handle ));

use RT::Extension::Converter::RT1::Config;
use DBI;

sub new {
    my $class = shift;

    my $self = $class->SUPER::new(@_);
    $self->config(RT::Extension::Converter::RT1::Config->new);
    return $self;
}

# this probably really wants to be using DBIx::SearchBuilder or
# some other ORM, but we're really just doing a few simple SQL calls
# so we'll avoid having to map the old tables for now

sub _connect {
    my $self = shift;
    my $config = $self->config;
    
    my $dsn = sprintf("DBI:mysql:database=%s;host=%s;",
                      $config->database, $config->dbhost,
                      { RaiseError => 1 });
    print "connecting to $dsn" if $config->debug;
    my $dbh = DBI->connect($dsn, $config->dbuser, $config->dbpassword) 
        or die "Can't connect to RT1 database: ".$DBI::errstr;

    return $self->_handle($dbh);
}

sub _run_query {
    my $self = shift;
    my %args = @_;

    my $handle= $self->_handle|| $self->_connect;

    my @placeholders = @{$args{placeholders}||[]};
    
    my $sth = $handle->prepare($args{sql});
    $sth->execute(@placeholders) or 
      die("Can't run query: $args{sql} - " . 
          join(" ",@placeholders) . 
          "\nReason:" . $DBI::errstr . "\n");
    
    return $sth;
}

sub _fetch_data {
    my $self = shift;
    my %args = @_;
    my $name = delete $args{name};

    my $sth = $self->_sth($name);

    unless ($sth) {
        $sth = $self->_run_query( %args );
        $self->_sth( $name => $sth );
    }

    my $data = $sth->fetchrow_hashref;

    $self->_clean_sth($name) unless $data;

    return $data;
}

sub _sth {
    my $self = shift;

    if (@_ > 1) {
        my ($name,$sth) = @_;
        $self->{sths}{$name} = $sth;
    } elsif (@_) {
        my $name = shift;
        $self->{sths}{$name};
    } else {
        die "You must pass at least a name to _sth";
    }
}

sub _clean_sth {
    my $self = shift;
    my $name = shift;

    $self->_sth($name)->finish;
    $self->_sth($name,undef);
    return;
}

sub get_user {
    my $self = shift;

    my $sql = <<ESQL;
select user_id as Name, 
       real_name as RealName, 
       password as Password, 
       email as EmailAddress, 
       phone as WorkPhone, 
       comments as Comments, 
       admin_rt as SuperUser
from users
ESQL

    my $user_data = $self->_fetch_data( name => 'User', sql => $sql );

    if ($user_data && !$user_data->{EmailAddress}) {
        $user_data->{EmailAddress} = $user_data->{Name}.'@'.$self->config->email_domain;
    }

    return $user_data;
}

sub get_queue {
    my $self = shift;

    my $sql = <<ESQL;
select queue_id as Name, 
       mail_alias as CorrespondAddress, 
       comment_alias as CommentAddress, 
       default_prio as InitialPriority, 
       default_final_prio as FinalPriority, 
       default_due_in as DefaultDueIn
from queues
ESQL

    my $queue_data = $self->_fetch_data( name => 'Queue', sql => $sql );

    if ($queue_data) {
        $queue_data->{Description} = "Imported from RT 1.0";
    }

    return $queue_data;

}

sub get_area {
    my $self = shift;
    my %args = @_;

    my $sql = 'select area from queue_areas where queue_id = ?';

    my $area_data = $self->_fetch_data( name => 'Area', 
                                        sql => $sql, 
                                        placeholders => [$args{Name}] );

    return $area_data;
}

sub get_queue_acl {
    my $self = shift;
    my %args = @_;

    my $sql = 'select user_id, display, manipulate, admin from queue_acl where queue_id = ?';

    my $acl_data = $self->_fetch_data( name => 'ACL', 
                                       sql => $sql, 
                                       placeholders => [$args{Name}] );

    return $acl_data;
}

sub get_ticket {
    my $self = shift;
    my %args = @_;

    my $sql = <<SQL;
select serial_num as id,
       effective_sn as EffectiveId,
       status as Status,
       requestors as Requestors,
       owner as Owner,
       subject as Subject,
       priority as Priority,
       final_priority as FinalPriority,
       initial_priority as InitialPriority,
       date_due as Due,
       date_told as Told,
       date_created as Created,
       date_acted as Updated,
       queue_id as Queue,
       area as Area
from each_req 
SQL
    my $ticket_data = $self->_fetch_data( name => 'Ticket', sql => $sql );

    return $ticket_data;
}

sub get_transactions {
    my $self = shift;
    my $ticket_id = shift;
    my $transactions;

    my $sql = 'select * from transactions where serial_num = ? order by trans_date asc';
    while (my $transaction = $self->_fetch_data( name => 'Transaction', 
            sql => $sql, 
            placeholders => [$ticket_id]) ) {
        if ($transaction->{actor} && $transaction->{actor} !~ /\@/) {
            $transaction->{actor} .= '@'.$self->config->email_domain;
        }
        push @$transactions,$transaction;
    }
    return $transactions;
}

1;