SVN::Notify::Filter::EmailFlatFileDB - Converts account names to email address based on a flat-file database

    svnnotify --repos-path "$1" --revision "$2" ..etc..  \
              --filter EmailFlatFileDB                   \
                    --account_file /x/x/x/users.db         \
                    --account_field 3

    with a text file like other UNIX/Apache password files:

       user1:xxx:xxx:user1@example.com
       user2:xxx:xxx:user2@example.com

    perldoc SVN::Notify::Filter::EmailFlatFileDB

package SVN::Notify::Filter::EmailFlatFileDB;

use warnings;
use strict;
use SVN::Notify;
use Carp;

our $VERSION = '1.01';

SVN::Notify->register_attributes(
                                 account_file  => 'account_file=s',
                                 account_field => 'account_field=i',


                                 );

my %allusers;  # key=account name, value=array reference to fields from the file
my $SPLITCHAR = ':';
my $debug = 0;

# The first argument is the SVN::Notify object
# The second argument is the sender account name or address.

sub from {
  my ($notifier, $from) = @_;
  my $dbfield= $notifier->account_field;

  if ($debug) { print "EmailFlatFileDB From: $from ($dbfield)"; }

  # load database... I'm not sure if the order of from/to
  # is always going to be fixed
  if (! %allusers) {
    my $dbfile = $notifier->account_file;
    _loadPasswdDb($dbfile,\%allusers,$dbfield);
    if ($debug) { _writePasswdDb(\%allusers); }
  }

  ($from) = _translateEmails(\%allusers,$dbfield,$from);
  if ($debug) { print " translated to: $from\n"; }

  return $from;
}

# The first argument is the SVN::Notify object
# The second argument is an array reference to the recipients.
sub recipients {
  my ($notifier, $recip) = @_;

  my $dbfield= $notifier->account_field;

  if ($debug) { print 'EmailFlatFileDB to: ' . join(',',@$recip) . "\n"; }

  # if the file hasn't been loaded yet, do so
  if (! %allusers) {
    my $dbfile = $notifier->account_file;
    _loadPasswdDb($dbfile,\%allusers,$dbfield);
    if ($debug) { _writePasswdDb(\%allusers); }
  }

  @$recip = _translateEmails(\%allusers,$dbfield,@$recip);

  return $recip;
}

#################################################################
#
# Helper functions
#

sub _loadPasswdDb {
  my $passwd_file = shift;
  my $db = shift; # this is a hash (key=username, val=array [user fields])
  my $maxfields = shift; # number of fields needed to store

  open (INFILE, $passwd_file) or croak "Can't open email/account file $passwd_file: $!";

  while (<INFILE>) {
    chomp;
    if (/^\w*$/) { next; } # all whitespace
    if (/^\w*#/) { next; } # hash is a comment

    my @line = split($SPLITCHAR);
    $#line = $maxfields; # Only keep the number of fields needed
    $$db{lc(shift(@line))} = \@line;
  }

  close INFILE;
}

sub _writePasswdDb {
  my %db = %{shift(@_)};

  print "EmailFlatFileDB: Users in DB......\n";
  for my $user (keys(%db)) {
    my $attrs = $db{$user};
    print "  $user: " . join('|',@$attrs) . "\n";
  }
}

# Uses the hash of user information to return a list of
# email addresses, given a list of usernames.  Note that the
# two arrays are not necessarily of the same size, as users
# that are not in the db are dropped.

sub _translateEmails {
  my $allusers = shift; # users hash
  my $emailfield = shift; # index of the email field
  # the rest of the arguments are the actual users

  my @emails = ();

  for my $thisuser (@_) {
    $thisuser = lc($thisuser);
    if (length($thisuser)==0) {
        # no accountname
        next;
    }
    if ($thisuser =~ /@/) {
      if ($debug >=2) { print "EmailFlatFileDB: $thisuser is already an email address\n"; }
      push(@emails,$thisuser);
      next;
    }
    if (exists($$allusers{$thisuser})) {
      if ($debug >= 2) { print "EmailFlatFileDB: found $thisuser / " . $$allusers{$thisuser}[$emailfield-1]; }
      push(@emails, $$allusers{$thisuser}[$emailfield-1]);
    } else {
      if ($debug) { print "Skipping $thisuser as there is no email record for them.\n"; }
    }
  }

  return @emails;
}

1; # End of SVN::Notify::Filter::EmailFlatFileDB