SWISH::Prog::Aggregator::MailFS - crawl a filesystem of email messages

 use SWISH::Prog::Aggregator::MailFS;
 my $fs = SWISH::Prog::Aggregator::MailFS->new(
        indexer => SWISH::Prog::Indexer->new
    );

 $fs->indexer->start;
 $fs->crawl( $path_to_mail );
 $fs->indexer->finish;

    perldoc SWISH::Prog

package SWISH::Prog::Aggregator::MailFS;
use strict;
use warnings;
use base qw( SWISH::Prog::Aggregator::FS );
use Path::Class ();
use SWISH::Prog::Aggregator::Mail;    # delegate doc creation
use Carp;
use Data::Dump qw( dump );

our $VERSION = '0.51';

sub init {
    my $self = shift;
    $self->SUPER::init(@_);

    # cache a Mail aggregator to use its get_doc method
    $self->{_mailer} = SWISH::Prog::Aggregator::Mail->new(
        indexer => $self->indexer,
        verbose => $self->verbose,
        debug   => $self->debug,
    );

    return $self;
}

sub file_ok {
    my $self      = shift;
    my $full_path = shift;
    my $stat      = shift;

    $self->debug and warn "checking file $full_path\n";

    return 0 if $full_path =~ m![\\/](\.svn|RCS)[\\/]!; # TODO configure this.

    $stat ||= [ stat($full_path) ];
    return 0 unless -r _;
    return 0 if -d _;
    if (    $self->ok_if_newer_than
        and $self->ok_if_newer_than >= $stat->[9] )
    {
        return 0;
    }
    return 0
        if ( $self->_apply_file_rules($full_path)
        && !$self->_apply_file_match($full_path) );

    $self->debug and warn "  $full_path -> ok\n";
    if ( $self->verbose & 4 ) {
        local $| = 1;    # don't buffer
        print "crawling $full_path\n";
    }

    return $full_path;
}

sub get_doc {
    my $self = shift;

    # there's some wasted overhead here in creating a
    # SWISH::Prog::Doc 2x. But we're optimizing here for
    # developer time...

    # mostly a slurp convenience
    my $doc = $self->SUPER::get_doc(@_);

    #carp "first pass for raw doc: " . dump($doc);

    # get the "folder"
    my $folder = Path::Class::file( $doc->url )->dir;

    # now convert the buffer to an email message
    my $msg = Mail::Message->read( \$doc->content );

    # and finally convert to the SWISH::Prog::Doc we intend to return
    my $mail = $self->{_mailer}->get_doc( $folder, $msg );
    
    # reinstate original url from filesystem
    $mail->url($doc->url);

    #carp "second pass for mail doc: " . dump($mail);

    return $mail;
}

1;

__END__