SWISH::Prog::Indexer - base indexer class

 use SWISH::Prog::Indexer;
 my $indexer = SWISH::Prog::Indexer->new(
        invindex    => SWISH::Prog::InvIndex->new,
        config      => SWISH::Prog::Config->new,
        count       => 0,
        clobber     => 1,
        flush       => 10000,
        started     => time()
 );
 $indexer->start;
 for my $doc (@list_of_docs) {
    $indexer->process($doc);
 }
 $indexer->finish;

    perldoc SWISH::Prog

package SWISH::Prog::Indexer;
use strict;
use warnings;
use base qw( SWISH::Prog::Class );
use Scalar::Util qw( blessed );
use Carp;
use Data::Dump qw( dump );
use SWISH::Prog::Config;

our $VERSION = '0.51';

__PACKAGE__->mk_accessors(
    qw( invindex config count clobber flush started test_mode ));

sub init {
    my $self = shift;
    $self->SUPER::init(@_);
    if (    exists $self->{config}
        and defined $self->{config}
        and !blessed( $self->{config} )
        and $self->{config} !~ m/<swish>|\.xml$/ )
    {
        $self->{config}
            = $self->verify_isa_swish_prog_config( $self->{config} );
    }
    $self->{config} ||= SWISH::Prog::Config->new;
    return $self;
}

sub start {
    my $self = shift;
    if ( !defined $self->invindex ) {
        croak "Missing invindex object";
    }
    if (   !blessed( $self->invindex )
        or !$self->invindex->can('open') )
    {
        croak
            "Invalid invindex: either not blessed object or does not implement 'open' method";
    }

    $self->invindex->open;
    $self->{started} = time();
}

sub process {
    my $self = shift;
    my $doc  = shift;
    unless ( $doc && blessed($doc) && $doc->isa('SWISH::Prog::Doc') ) {
        croak "SWISH::Prog::Doc object required";
    }

    $self->start unless $self->started;

    $self->{count}++;

    return $doc;
}

sub finish {
    my $self = shift;
    $self->invindex->close;
}

# NOTE in _verify_swish3_config() below,
# if config is already in swish3 format, must
# override param value with SWISH::Prog::Config object
# after adding to SWISH::3::Config object so that the
# aggregator using this Indexer is happy.

sub _verify_swish3_config {
    my $self = shift;

    if ( !exists $self->{config} ) {
        return;
    }

    #carp dump $self->{config};

    # isa object
    if ( blessed( $self->{config} ) ) {
        $self->{config}
            = $self->verify_isa_swish_prog_config( $self->{config} );
        my $swish_3_config = $self->{config}->ver2_to_ver3();
        $self->{s3}->config->add($swish_3_config);
    }

    # xml string
    elsif ( $self->{config} =~ m/<swish>|[\n\r]/ ) {
        $self->{s3}->config->add( $self->{config} );
        $self->{config} = SWISH::Prog::Config->new();
    }

    # file
    elsif ( -r $self->{config} ) {

        # swish3 format
        if ( $self->{config} =~ m/\.xml/ ) {
            $self->{s3}->config->add( $self->{config} );
            $self->{config} = SWISH::Prog::Config->new();
        }

        # swish2 format
        else {
            $self->{config}
                = $self->verify_isa_swish_prog_config( $self->{config} );
            my $swish_3_config = $self->{config}->ver2_to_ver3();
            $self->{s3}->config->add($swish_3_config);
        }

    }

    # no support
    else {
        croak
            "Unsupported config format (not a XML string, filename or SWISH::Prog::Config object): $self->{config}";
    }

    return $self->{config};
}
1;

__END__