SWISH::Prog::Searcher - base searcher class

SWISH-Prog documentation Contained in the SWISH-Prog distribution.

Index

Code Index:

NAME

Top

SWISH::Prog::Searcher - base searcher class

SYNOPSIS

Top

 my $searcher = SWISH::Prog::Searcher->new(
                    invindex        => 'path/to/index',
                    max_hits        => 1000,
                );

 my $results = $searcher->search( 'foo bar' );
 while (my $result = $results->next) {
     printf("%4d %s\n", $result->score, $result->uri);
 }

DESCRIPTION

Top

SWISH::Prog::Searcher is a base searcher class. It defines the APIs that all SWISH::Prog storage backends adhere to in returning results from a SWISH::Prog::InvIndex.

METHODS

Top

init

Overrides base method.

invindex

A SWISH::Prog::InvIndex object or directory path. Required. Set in new().

May be a single value or an array ref of values (for searching multiple indexes at once).

max_hits

The maximum number of hits to return. Optional. Default is 1000.

search( query )

Returns a SWISH::Prog::Results object.

AUTHOR

Top

Peter Karman, <perl@peknet.com>

BUGS

Top

Please report any bugs or feature requests to bug-swish-prog at rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=SWISH-Prog. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

Top

You can find documentation for this module with the perldoc command.

    perldoc SWISH::Prog

You can also look for information at:

* Mailing list

http://lists.swish-e.org/listinfo/users

* RT: CPAN's request tracker

http://rt.cpan.org/NoAuth/Bugs.html?Dist=SWISH-Prog

* AnnoCPAN: Annotated CPAN documentation

http://annocpan.org/dist/SWISH-Prog

* CPAN Ratings

http://cpanratings.perl.org/d/SWISH-Prog

* Search CPAN

http://search.cpan.org/dist/SWISH-Prog/

COPYRIGHT AND LICENSE

Top

Copyright 2008-2009 by Peter Karman

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

SEE ALSO

Top

http://swish-e.org/

SWISH-Prog documentation Contained in the SWISH-Prog distribution. 
package SWISH::Prog::Searcher;
use strict;
use warnings;
use base qw( SWISH::Prog::Class );
use Carp;
use Scalar::Util qw( blessed );

our $VERSION = '0.51';

__PACKAGE__->mk_accessors(
    qw(
        max_hits
        invindex
        ),
);


sub init {
    my $self = shift;
    $self->SUPER::init(@_);

    $self->{max_hits} ||= 1000;

    # set up invindex
    if ( !$self->{invindex} ) {
        croak "invindex required";
    }

    # force into an array
    if ( ref $self->{invindex} ne 'ARRAY' ) {
        $self->{invindex} = [ $self->{invindex} ];
    }

    for my $invindex ( @{ $self->{invindex} } ) {
        if ( !blessed($invindex) ) {

            # assume a InvIndex in the same namespace as $self
            my $class = ref($self);
            $class =~ s/::Searcher$/::InvIndex/;
            eval "require $class";
            croak $@ if $@;
            $invindex = $class->new( path => $invindex, clobber => 0 );

            #warn "new invindex in $class";

        }
        $invindex->open_ro;
    }

    return $self;
}


sub search {
    croak "you must override search() in your subclass";
}

1;

__END__