Samba::LDAP::Config - Config file related tasks for Samba::LDAP

    use Samba::LDAP::Config;

    my $config = Samba::LDAP::Config->new()
        or die "Can't create object\n";

    # Returns where smbldap.conf, smbldap_bind.conf and
    # smb.conf are located
    my $smbldap_conf = $config->find_smbldap();    
    my $smbldap_bind_conf = $config->find_smbldap_bind();
    my $samba_conf = $config->find_samba();

    my $smbldap_conf = $config->find_smbldap();

    my $smbldap_bind_conf = $config->find_smbldap_bind();

    my $smb_conf = $config->find_samba();

    my $conf = $config->read_conf( $filename );

package Samba::LDAP::Config;

require 5.006;

use warnings;
use strict;
use Readonly;
use Regexp::DefaultFlags;
use base qw( Config::Tiny );

our $VERSION = '0.05';

#
# Add Log::Log4perl to all our classes!!!!
#

# Regexp to save param and value in param="value", excluding ""
Readonly my $SPLIT_ON_EQUALS_SIGN => qr{
                                                                                  \A       # Start of string 
                                                                                  \s*      # Whitespace 0 or more
                                                                                  ([^=]+?) # = is terminator of
                                                                                                    # optionally match 1 
                                                                                                    # or more
                                                                                  \s* 
                                                                                  =        # Actual =
                                                                                  \s* 
                                                                                  "        # Actual "
                                                                                  ([^"]*)  # " is terminator of
                                                                                                    # match 0 or more
                                                                                  " 
                                                                                  \s* 
                                                                                  \z       # End of string
                                                                              };

# Regexp for ${suffix}
Readonly my $SUFFIX_CHARS => qr{ \$ [{] suffix [}] \z};

# Move this up here from read_string. Will benchmark later.
Readonly my $COMMENTS_AND_EMPTY_LINES => qr{
                                                                                          \A   # Start of string
                                                                                          \s*  # Whitespace 0 or more

                                                                                          # Match one or the other
                                                                                          ( ?: [#] | [;] | \z )
                                                                                      };

#========================================================================
#                         -- PUBLIC METHODS --
#========================================================================

#------------------------------------------------------------------------
# find_smbldap()
#
# Looks for smbldap.conf
#------------------------------------------------------------------------

sub find_smbldap {
    my $self = shift;

    if ( -e '/etc/smbldap-tools/smbldap.conf' ) {
        $self->{smbldap_conf} = '/etc/smbldap-tools/smbldap.conf';
    }
    elsif ( -e '/etc/opt/IDEALX/smbldap-tools/smbldap.conf' ) {
        $self->{smbldap_conf} = '/etc/opt/IDEALX/smbldap-tools/smbldap.conf';
    }
    else {
        if ( -d 't' ) {
            chdir 't';
        }
        $self->{smbldap_conf} = 'smbldap.conf';
    }

    # Add more locations here (don't really like this technique) or use
    # Config::Find - Same applies for below two methods

    return $self->{smbldap_conf};
}

#------------------------------------------------------------------------
# find_smbldap_bind()
#
# Looks for smbldap_bind.conf
#------------------------------------------------------------------------

sub find_smbldap_bind {
    my $self = shift;

    if ( -e '/etc/smbldap-tools/smbldap_bind.conf' ) {
        $self->{smbldap_bind_conf} = '/etc/smbldap-tools/smbldap_bind.conf';
    }
    elsif ( -e '/etc/opt/IDEALX/smbldap-tools/smbldap_bind.conf' ) {
        $self->{smbldap_bind_conf} =
          '/etc/opt/IDEALX/smbldap-tools/smbldap_bind.conf';
    }
    else {
        if ( -d 't' ) {
            chdir 't';
        }
        $self->{smbldap_bind_conf} = 'smbldap_bind.conf';
    }

    return $self->{smbldap_bind_conf};
}

#------------------------------------------------------------------------
# find_samba()
#
# Looks for smb.conf
#------------------------------------------------------------------------

sub find_samba {
    my $self = shift;

    if ( -e '/etc/samba/smb.conf' ) {
        $self->{samba_conf} = '/etc/samba/smb.conf';
    }
    elsif ( -e 'usr/local/samba/lib/smb.conf' ) {
        $self->{samba_conf} = '/usr/local/samba/lib/smb.conf';
    }
    else {
        if ( -d 't' ) {
            chdir 't';
        }
        $self->{samba_conf} = 'smb.conf';
    }

    return $self->{samba_conf};
}

#------------------------------------------------------------------------
# read_conf( $filename )
#
# Wrapper to provide an instant error message as returned by the native
# Config::Tiny read method
#------------------------------------------------------------------------

sub read_conf {
    my $self = shift;
    my $file = shift;

    my $conf = $self->read($file);

    # Nice instant user error message
    die $self->errstr() . "\nPlease fix this to continue!\n"
      if $self->errstr();

    return $conf;
}

#------------------------------------------------------------------------
# read_string()
#
# Overrides Config::Tiny's read_string to exclude the " " marks found in
# smbldap.conf and smbldap_bind.conf and remove section handling, as we
# don't have any [sections] in either of these files.
#
# Also substitutes the suffix hash ( ${suffix} ) with its value
#------------------------------------------------------------------------

sub read_string {
    my $class = ref $_[0] ? ref shift: shift;
    my $self = bless {}, $class;
    return undef if !defined $_[0];

    # Parse the file
    my $counter = 0;
    foreach ( split /(?:\015{1,2}\012|\015|\012)/, shift ) {
        $counter++;

        # Skip comments and empty lines
        next if /$COMMENTS_AND_EMPTY_LINES/;

        # Handle properties, but don't save " " and S&R ${suffix}
        if (/$SPLIT_ON_EQUALS_SIGN/) {
            my ( $before_equals, $after_equals ) = ( $1, $2 );

            # Save what's after suffix=, temporarily. (don't like this
            # technique, will come back to it later though)
            if ( $before_equals eq 'suffix' ) {
                $self->{sf_val} = $after_equals;
            }

            # Replace ${suffix} with what was saved above
            $after_equals =~ s{ $SUFFIX_CHARS }{$self->{sf_val}};

            # as normal
            $self->{$before_equals} = $after_equals;
            next;
        }

        return $self->_error("Syntax error at line $counter: '$_'");
    }

    # Not needed for returning
    delete $self->{sf_val};

    return $self;
}

#========================================================================
#                         -- PRIVATE METHODS --
#========================================================================

1;    # Magic true value required at end of module

__END__