Search::Indexer::Incremental::MD5::Searcher - Search your indexed files

  


  my $search_string = 'find_me' ;
  my $searcher = 
	eval 
	{
	Search::Indexer::Incremental::MD5::Searcher->new
		(
		USE_POSITIONS => 1, 
		INDEX_DIRECTORY => 'text_index', 
		get_perl_word_regex_and_stop_words(),
		)
	} or croak "No full text index found! $@\n" ;

  my $results = $searcher->search($search_string) ;

  # sort in decreasing score order
  my @indexes = map { $_->[0] }
		    reverse
		        sort { $a->[1] <=> $b->[1] }
			    map { [$_, $results->[$_]{SCORE}] }
			        0 .. $#$results ;

  for (@indexes)
	{
	print {* STDOUT} "$results->[$_]{PATH} [$results->[$_]{SCORE}].\n" ;
	}

  $searcher = undef ;

  my $indexer = new Search::Indexer::Incremental::MD5::Searcher(%named_arguments) ;

	Nadim ibn hamouda el Khemir
	CPAN ID: NKH
	mailto: nadim@cpan.org

    perldoc Search::Indexer::Incremental::MD5

package Search::Indexer::Incremental::MD5::Searcher ;

use strict;
use warnings ;
use Carp qw(carp croak confess) ;

BEGIN 
{
use Sub::Exporter -setup => 
	{
	exports => [ qw() ],
	groups  => 
		{
		all  => [ qw() ],
		}
	};
	
use vars qw ($VERSION);
$VERSION     = '0.02';
}

#----------------------------------------------------------------------------------------------------------

use Time::HiRes     qw/time/;
use Search::Indexer 0.75;
use Search::Indexer::Incremental::MD5 ;
use BerkeleyDB;
use English qw( -no_match_vars ) ;
use Readonly ;

#----------------------------------------------------------------------------------------------------------

sub new
{

my ($class, %arguments) = @_ ;

my $index_directory = $arguments{INDEX_DIRECTORY} or croak 'Error: index directory missing' ;
-d $index_directory or croak "Error: can't find the index directory '$index_directory': $!";

Readonly my $ID_TO_METADATA_FILE => 'id_to_docs_metadata.bdb' ;

# use id_to_docs_metadata.bdb, to store a lookup from the uniq id 
# to the document metadata {$doc_id => "$md5\t$path"}
tie my %id_to_metadata, 'BerkeleyDB::Hash',  ## no critic (Miscellanea::ProhibitTies)
	-Filename => "$index_directory/$ID_TO_METADATA_FILE", 
	-Flags    => DB_CREATE
		or croak "Error: opening '$index_directory/$ID_TO_METADATA_FILE': $^E $BerkeleyDB::Error";

return 
	bless 
		{
		INDEXER => new Search::Indexer
					(
					writeMode => 0,
					dir       => $index_directory,
					#~ preMatch  => '[[',
					#~ postMatch => ']]',
					) ,
					
		ID_TO_METADATA => \%id_to_metadata,
		USE_POSITIONS => $arguments{USE_POSITIONS} , 
		INDEX_DIRECTORY => $arguments{INDEX_DIRECTORY}, 
		}, $class ;
}

#----------------------------------------------------------------------------------------------------------

sub words
{

my ($self, $prefix) = @_ ;

return $self->{INDEXER}->words($prefix) ;
}
	
#----------------------------------------------------------------------------------------------------------

sub search
{

my ($self, %arguments) = @_ ;

my $search_string = $arguments{SEARCH_STRING} ;

# force Some::Module::Name into "Some::Module::Name" to prevent 
# interpretation of ':' as a field name by Query::Parser
$search_string =~ s/(^|\s)([\w]+(?:::\w+)+)(\s|$)/$1"$2"$3/smxg;

my $search_results = $self->{INDEXER}->search($search_string, 'implicit_plus');

my @matching_files ;

foreach my $matching_id (keys %{$search_results->{scores}}) 
	{
	if(exists $self->{ID_TO_METADATA}{$matching_id})
		{
		my ($md5, $path, $description) = split qr/\t/smx, $self->{ID_TO_METADATA}{$matching_id};
		
		push @matching_files,
			{
			SCORE => $search_results->{scores}{$matching_id},
			PATH => $path,
			DESCRIPTION => $description,
			MD5 => $md5,
			ID => $matching_id,
			} ;
		}
	else
		{
		#~ carp "matching id '$matching_id' corresponds to removed document!\n" ;
		}
	}
	
return \@matching_files ;
}

#----------------------------------------------------------------------------------------------------------

sub match_description
{

my ($self, %arguments) = @_ ;

my $search_string = $arguments{SEARCH_STRING} ;

my @matching_files ;

for my $id (keys %{$self->{ID_TO_METADATA}}) 
	{
	my ($md5, $path, $description) = split qr/\t/smx, $self->{ID_TO_METADATA}{$id};
	
	if(defined $description && $description =~$search_string)
		{
		push @matching_files,
			{
			PATH => $path,
			DESCRIPTION => $description,
			MD5 => $md5,
			ID => $id,
			} ;
		}
	}
	
return \@matching_files ;
}

#----------------------------------------------------------------------------------------------------------

1 ;