Search::Tools::Object - base class for Search::Tools objects

 package MyClass;
 use base qw( Search::Tools::Object );

 __PACKAGE__->mk_accessors( qw( foo bar ) );

 sub init {
    my $self = shift;
    $self->SUPER::init(@_);

    # do stuff to set up object

 }

 1;

 # elsewhere

 use MyClass;
 my $object = MyClass->new;
 $object->foo(123);
 print $object->bar . "\n";

    perldoc Search::Tools

package Search::Tools::Object;
use strict;
use warnings;
use Carp;
use base qw( Rose::ObjectX::CAF );
use Scalar::Util qw( blessed );
use Search::Tools::MethodMaker;

our $VERSION = '0.59';

__PACKAGE__->mk_accessors(qw( debug ));

sub _init {
    croak "use init() instead";
}

sub init {

    #Carp::cluck();
    my $self = shift;

    #Carp::carp("self shifted");
    $self->SUPER::init(@_);

    #Carp::carp("self inited");
    $self->{debug} ||= $ENV{PERL_DEBUG} || 0;

    #Carp::carp("debug set");
    return $self;
}

# called by some subclasses
sub _normalize_args {
    my $self  = shift;
    my %args  = @_;
    my $q     = delete $args{query};
    my $debug = delete $args{debug};
    if ( !defined $q ) {
        croak "query required";
    }
    if ( !ref($q) ) {
        require Search::Tools::QueryParser;
        $args{query} = Search::Tools::QueryParser->new(
            debug => $debug,
            map { $_ => delete $args{$_} }
                grep { Search::Tools::QueryParser->can($_) } keys %args
        )->parse($q);
    }
    elsif ( ref($q) eq 'ARRAY' ) {
        warn "query ARRAY ref deprecated as of version 0.24";
        $args{query} = Search::Tools::QueryParser->new(
            debug => $debug,
            map { $_ => delete $args{$_} }
                grep { Search::Tools::QueryParser->can($_) } keys %args
        )->parse( join( ' ', @$q ) );
    }
    elsif ( blessed($q) and $q->isa('Search::Tools::Query') ) {
        $args{query} = $q;
    }
    elsif ( blessed($q) and $q->isa('Search::Tools::RegExp::Keywords') ) {

        # backcompat
        $args{query} = Search::Tools::Query->from_regexp_keywords($q);
    }
    else {
        croak
            "query param required to be a scalar string or Search::Tools::Query object";
    }
    $args{debug} = $debug;  # restore so it can be passed on
    return %args;
}

1;

__END__