Socialtext::Resting::LocalCopy - Maintain a copy on disk of a workspace

package Socialtext::Resting::LocalCopy;
use strict;
use warnings;
use JSON::XS;

our $VERSION = '0.01';

sub new {
    my $class = shift;
    my $self = { @_ };

    die 'rester is mandatory' unless $self->{rester};
    bless $self, $class;
    return $self;
}

sub pull {
    my $self = shift;
    my %opts = @_;
    my $dir  = $opts{dir};
    my $tag  = $opts{tag};
    my $r    = $self->{rester};

    $r->accept('text/plain');
    my @pages = $tag ? $r->get_taggedpages($tag) : $r->get_pages();
    $r->accept('application/json');
    $r->json_verbose(1);
    for my $p (@pages) {
        print "Saving $p ...\n";
        my $obj = decode_json($r->get_page($p));

        # Trim the content
        my %to_keep = map { $_ => 1 } $self->_keys_to_keep;
        for my $k (keys %$obj) {
            delete $obj->{$k} unless $to_keep{$k};
        }

        my $wikitext_file = "$dir/$obj->{page_id}";
        open(my $fh, ">$wikitext_file") or die "Can't open $wikitext_file: $!";
        binmode $fh, ':utf8';
        print $fh delete $obj->{wikitext};
        close $fh or die "Can't write $wikitext_file: $!";

        my $json_file = "$wikitext_file.json";
        open(my $jfh, ">$json_file") or die "Can't open $json_file: $!";
        print $jfh encode_json($obj);
        close $jfh or die "Can't write $json_file: $!";
    }
}

sub _keys_to_keep { qw/page_id name wikitext tags/ }

sub push {
    my $self = shift;
    my %opts = @_;
    my $dir  = $opts{dir};
    my $tag  = $opts{tag};
    my $r    = $self->{rester};

    die "Sorry - push by tag is not yet implemented!" if $tag;

    my @files = glob("$dir/*.json");
    for my $f (@files) {
        open(my $fh, $f) or die "Can't open $f: $!";
        local $/ = undef;
        my $obj = decode_json(<$fh>);
        close $fh;

        (my $wikitext_file = $f) =~ s/\.json$//;
        open(my $wtfh, $wikitext_file) or die "Can't open $wikitext_file: $!";
        $obj->{wikitext} = <$wtfh>;
        close $wtfh;

        print "Putting $obj->{page_id} ...\n";
        $r->put_page($obj->{name}, $obj->{wikitext});
        $r->put_pagetag($obj->{name}, $_) for @{ $obj->{tags} };
    }
}

1;