Speech::Recognizer::ScLite::Line - Stores a single datum for use in

package Speech::Recognizer::ScLite::Line;

use 5.006;
use strict;
use warnings;
use Carp;

our $VERSION = '0.01';

##################################################################
# set up a whole bunch of default object management code.
# ask Class::MethodMaker to build methods:
use Class::MethodMaker 

    # constructor that calls 'init'
    new_with_init => 'new',

    # initializer that sets an instance's data from a hash
    # (private by convention of leading _)
    new_hash_init => '_hash_init',

    # methods to access/modify scalar data fields
    get_set => [ qw / ref hyp wf_id sort_key / ];

##################################################################
# if new() gets any arguments, they'll be passed here.
# Regardless of whether it does, we want to initialize at least a few
# fields in the instance.
sub init ($;%) {
    my ($self) = shift;
    my (%args) = @_;

    # check for abuse
    if (not defined $args{wf_id}) {
	croak "->new() invoked without (wf_id => ...) argument pair";
    }

    # set default values for some data fields
    if (not defined $args{sort_key}) {
	use File::Basename 'dirname';
	$args{sort_key} = dirname('wf_id');
    }

    # force users to defined all fields at initialization:
    if (not defined $args{ref}) {
	croak "'ref' => ...  not specified to new()";
    }
    if (not defined $args{hyp}) {
	croak "'hyp' => ...  not specified to new()";
    }
    # invoke the appropriate initializers
    $self->_hash_init(%args);
}
##################################################################
# shared only out to clan (Speech::Recognizer::ScLite::*)
sub _write_hyp ($$) {
    my ($self) = shift;
    my ($fh) = shift;
    croak "_write_hyp expects exactly 1 filehandle arg" 
	if not defined $fh or scalar @_;
    $self->_write_line($fh, $self->hyp);
}
##################################################################
# shared only out to clan (Speech::Recognizer::ScLite::*)
sub _write_ref ($$) {
    my ($self) = shift;
    my ($fh) = shift;
    croak "_write_ref expects exactly 1 filehandle arg" 
	if not defined $fh or scalar @_;
    $self->_write_line($fh, $self->ref);
}
##################################################################
# generic function, shared only internally
sub _write_line($$$) {
    my ($self) = shift;
    my ($fh) = shift;
    my ($text) = shift;
    print { $fh } $text, "\t(", $self->sort_key, '_', $self->wf_id, ")\n";
}
##################################################################

1;
__END__
# Documentation below.