String::CamelCase - camelcase, de-camelcase

 use String::CamelCase qw(camelize decamelize wordsplit);
 print camelize("some_keyword");  # ==> SomeKeyword
 print decamelize("SomeKeyword"); # ==> some_keyword
 print wordsplit("some_keyword"); # ==> (some, keyword)
 print wordsplit("SomeKeyword");  # ==> (Some, Keyword)

    perldoc String::CamelCase

## ----------------------------------------------------------------------------
# String::CamelCase
# -----------------------------------------------------------------------------
# Mastering programmed by YAMASHINA Hio
#
# Copyright 2006 YAMASHINA Hio
# -----------------------------------------------------------------------------
# $Id$
# -----------------------------------------------------------------------------
package String::CamelCase;

use warnings;
use strict;

our $VERSION = '0.02';

use base qw(Exporter);
our @EXPORT_OK = qw(camelize decamelize wordsplit);

1;

sub wordsplit
{
	my $s = shift;
	split( /[_\s]+|\b|(?<![A-Z])(?=[A-Z])|(?<=[A-Z])(?=[A-Z][a-z])/, $s );
}

sub camelize
{
	my $s = shift;
	join('', map{ ucfirst $_ } split(/(?<=[A-Za-z])_(?=[A-Za-z])|\b/, $s));
}

sub decamelize
{
	my $s = shift;
	$s =~ s{([^a-zA-Z]?)([A-Z]*)([A-Z])([a-z]?)}{
				my $fc = pos($s)==0;
				my ($p0,$p1,$p2,$p3) = ($1,lc$2,lc$3,$4);
				my $t = $p0 || $fc ? $p0 : '_';
				$t .= $p3 ? $p1 ? "${p1}_$p2$p3" : "$p2$p3" : "$p1$p2";
				$t;
		}ge;
	$s;
}

__END__

# -----------------------------------------------------------------------------
# End of File.
# -----------------------------------------------------------------------------