Sys::Statistics::Linux::DiskUsage - Collect linux disk usage.

Sys-Statistics-Linux documentation Contained in the Sys-Statistics-Linux distribution.

Index

Code Index:

NAME

Top

Sys::Statistics::Linux::DiskUsage - Collect linux disk usage.

SYNOPSIS

Top

    use Sys::Statistics::Linux::DiskUsage;

    my $lxs  = new Sys::Statistics::Linux::DiskUsage;
    my $stat = $lxs->get;

DESCRIPTION

Top

Sys::Statistics::Linux::DiskUsage gathers the disk usage with the command df.

For more information read the documentation of the front-end module Sys::Statistics::Linux.

DISK USAGE INFORMATIONS

Top

Generated by /bin/df -kP.

    total       -  The total size of the disk.
    usage       -  The used disk space in kilobytes.
    free        -  The free disk space in kilobytes.
    usageper    -  The used disk space in percent.
    mountpoint  -  The moint point of the disk.

GLOBAL VARS

If you want to change the path or arguments for df you can use the following variables...

    $Sys::Statistics::Linux::DiskUsage::DF_PATH = '/bin';
    $Sys::Statistics::Linux::DiskUsage::DF_CMD  = 'df -akP';

Example:

    use Sys::Statistics::Linux;
    use Sys::Statistics::Linux::DiskUsage;
    $Sys::Statistics::Linux::DiskUsage::DF_CMD = 'df -akP';

    my $sys  = Sys::Statistics::Linux->new(diskusage => 1);
    my $disk = $sys->get;

METHODS

Top

new()

Call new() to create a new object.

    my $lxs = Sys::Statistics::Linux::DiskUsage->new;

It's possible to set the path to df.

     Sys::Statistics::Linux::DiskUsage->new(
        cmd => {
            # This is the default
            path => '/bin',
            df   => 'df -kP 2>/dev/null',
        }
    );

get()

Call get() to get the statistics. get() returns the statistics as a hash reference.

    my $stat = $lxs->get;

EXPORTS

Top

No exports.

SEE ALSO

Top

df(1)

REPORTING BUGS

Top

Please report all bugs to <jschulz.cpan(at)bloonix.de>.

AUTHOR

Top

Jonny Schulz <jschulz.cpan(at)bloonix.de>.

COPYRIGHT

Top

Copyright (c) 2006, 2007 by Jonny Schulz. All rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Sys-Statistics-Linux documentation Contained in the Sys-Statistics-Linux distribution. 
package Sys::Statistics::Linux::DiskUsage;

use strict;
use warnings;
use Carp qw(croak);

our $VERSION = '0.14';
our $DF_PATH = undef;
our $DF_CMD  = undef;

sub new {
    my $class = shift;
    my $opts  = ref($_[0]) ? shift : {@_};

    my %self = (
        cmd => {
            path => '/bin',
            df   => 'df -kP 2>/dev/null',
        }
    );

    foreach my $p (keys %{ $opts->{cmd} }) {
        $self{cmd}{$p} = $opts->{cmd}->{$p};
    }

    return bless \%self, $class;
}

sub get {
    my $self   = shift;
    my $class  = ref $self;
    my $cmd    = $self->{cmd};
    my $df_cmd = $DF_CMD || $cmd->{df};
    my (%disk_usage);

    local $ENV{PATH} = $DF_PATH || $cmd->{path};
    open my $fh, "$df_cmd|" or croak "$class: unable to execute '$df_cmd' ($!)";

    # filter the header
    {my $null = <$fh>;}

    while (my $line = <$fh>) {
        next unless $line =~ /^(.+?)\s+(.+)$/;

        @{$disk_usage{$1}}{qw(
            total
            usage
            free
            usageper
            mountpoint
        )} = (split /\s+/, $2)[0..4];

        $disk_usage{$1}{usageper} =~ s/%//;
    }

    close($fh);
    return \%disk_usage;
}

1;