TAP::Formatter::JUnit - Harness output delegate for JUnit output

  prove --formatter TAP::Formatter::JUnit ...

  use TAP::Harness;
  my $harness = TAP::Harness->new( {
      formatter_class => 'TAP::Formatter::JUnit',
      merge => 1,
  } );
  $harness->runtests(@tests);

  Mark Aufflick
  Joe McMahon
  Michael Nachbaur
  Marc Abramowitz
  Colin Robertson
  Phillip Kimmey

package TAP::Formatter::JUnit;

use strict;
use warnings;
use XML::Generator;
use TAP::Formatter::JUnit::Session;
use base qw(TAP::Formatter::Console);
use Class::Field qw(field);

our $VERSION = '0.08';

field 'testsuites'  => [];

###############################################################################
# Subroutine:   open_test($test, $parser)
###############################################################################
# Over-ridden 'open_test()' method.
#
# Creates a 'TAP::Formatter::JUnit::Session' session, instead of a console
# formatter session.
sub open_test {
    my ($self, $test, $parser) = @_;
    my $session = TAP::Formatter::JUnit::Session->new( {
        name        => $test,
        formatter   => $self,
        parser      => $parser,
        passing_todo_ok => $ENV{ALLOW_PASSING_TODOS} ? 1 : 0,
    } );
    return $session;
}

###############################################################################
# Subroutine:   summary($aggregate)
###############################################################################
# Prints the summary report (in JUnit) after all tests are run.
sub summary {
    my ($self, $aggregate) = @_;
    return if $self->silent();

    my @suites = @{$self->testsuites};
    print { $self->stdout } $self->xml->testsuites( @suites );
}

###############################################################################
# Subroutine:   xml()
###############################################################################
# Returns a new 'XML::Generator', to generate XML output.
sub xml {
    my $self = shift;
    unless ($self->{xml}) {
        $self->{xml} = XML::Generator->new(
            ':pretty',
            ':std',
            'escape'   => 'always,high-bit,even-entities',
            'encoding' => 'UTF-8',
        );
    }
    return $self->{xml};
}

###############################################################################
# Subroutine:   xml_unescape()
###############################################################################
# Returns a new 'XML::Generator', to generate unescaped XML output.
sub xml_unescape {
    my $self = shift;
    unless ($self->{xml_unescape}) {
        $self->{xml_unescape} = XML::Generator->new(
            ':pretty',
            ':std',
            'escape'   => 'unescaped',
            'encoding' => 'UTF-8'
        );
    }
    return $self->{xml_unescape};
}

###############################################################################
# Subroutine:   add_testsuite($suite)
###############################################################################
# Adds the given XML test '$suite' to the list of test suites that we've
# executed and need to summarize.
sub add_testsuite {
    my ($self, $suite) = @_;
    push @{$self->testsuites}, $suite;
}

1;