Term::Pulse - show pulsed progress bar in terminal

    use Term::Pulse;
    pulse_start( name => 'Checking', rotate => 0, time => 1 ); # start the pulse
    sleep 3;
    pulse_stop()                                               # stop it

    Argument            Default
    ----------------------------
    name                'Working'
    rotate              0
    size                16
    time                0

    perldoc Term::Pulse

package Term::Pulse;

use warnings;
use strict;

our $VERSION = '0.03';
our @ISA = qw(Exporter);
our @EXPORT = qw(pulse_start pulse_stop);

use Time::HiRes qw(usleep time);
require Exporter;

my $pid;
my $global_name;
my $global_start_time;
my @mark = qw(- \ | / - \ | /);
$| = 1;

sub pulse_start {
    my %args = @_;
    my $name = defined $args{name}   ? $args{name}   : 'Working';
    my $type = defined $args{rotate} ? $args{rotate} : 0;
    my $size = defined $args{size}   ? $args{size}   : 16;
    my $time = defined $args{time}   ? $args{time}   : 0;
    my $start = time;
    $global_start_time = $start;

    $global_name = $name;

    $pid = fork and return;
    while (1) {
        foreach my $index (1..$size) {
            my $mark = $type ? $mark[$index % 8] : q{=};
            printf "$name...[%s%s%s]", q{ } x $index, $mark, q{ } x ($size - $index + 1);
            printf " (%f sec elapsed)\r", (time - $start) if $time;
            usleep 200000;
        }

        foreach my $index (1..$size) {
            my $mark = $type ? $mark[($index % 8) * -1] : q{=};
            printf "$name...[%s%s%s]", q{ } x ($size - $index + 1), $mark, q{ } x $index;
            printf " (%f sec elapsed)\r" , (time - $start ) if $time;
            usleep 200000;
        }
    }
}

sub pulse_stop {
    kill 9 => $pid;
    my $length = length($global_name);
    printf "$global_name%sDone%s\n", q{.} x (35 - $length), q{ } x 43;
    my $elapsed_time = time - $global_start_time;
    return $elapsed_time;
}

1; # End of Term::Pulse