Test::Chimps::Anna - An IRQ bot that announces test failures (and unexpected passes)

    use Test::Chimps::Anna;

    my $anna = Test::Chimps::Anna->new(
      server   => "irc.perl.org",
      port     => "6667",
      channels => ["#example"],

      nick      => "anna",
      username  => "nice_girl",
      name      => "Anna",
      database_file => '/path/to/chimps/chimpsdb/database',
      config_file => '/path/to/chimps/anna-config.yml',
      server_script => 'http://example.com/cgi-bin/chimps-server.pl'
      );

    $anna->run;

    perldoc Test::Chimps::Anna

package Test::Chimps::Anna;

use warnings;
use strict;

use Carp;
use Jifty::DBI::Handle;
use Test::Chimps::Report;
use Test::Chimps::ReportCollection;
use YAML::Syck;

use base 'Bot::BasicBot';

our $VERSION = '0.04';

sub new {
  my $class = shift;
  my $self = $class->SUPER::new(@_);
  $self = bless $self, $class;
  my %args = @_;
  if (! exists $args{database_file}) {
    croak "You must specify SQLite database file!";
  }
  if (exists $args{config_file}) {
    my $columns = LoadFile($args{config_file});
    foreach my $var (@$columns) {
      package Test::Chimps::Report::Schema;
      column($var, type(is('text')));
    }
  }
  $self->{database_file} = $args{database_file};
  
  $self->{handle} = Jifty::DBI::Handle->new();
  $self->{handle}->connect(driver => 'SQLite', database => $self->{database_file})
    or die "Couldn't connect to database";

  $self->{oid} = $self->_get_highest_oid;
  $self->{first_run} = 1;
  $self->{passing_projects} = {};
  return $self;
}

sub _get_highest_oid {
  my $self = shift;
  
  my $reports = Test::Chimps::ReportCollection->new(handle => $self->_handle);
  $reports->columns(qw/id/);
  $reports->unlimit;
  $reports->order_by(column => 'id', order => 'DES');
  $reports->rows_per_page(1);

  my $report = $reports->next;
  return $report->id;
}

sub _handle {
  my $self = shift;
  return $self->{handle};
}

sub _oid {
  my $self = shift;
  return $self->{oid};
}

sub tick {
  my $self = shift;

  if ($self->{first_run}) {
    $self->_say_to_all("I'm going to ban so hard");
    $self->{first_run} = 0;
  }

  my $reports = Test::Chimps::ReportCollection->new(handle => $self->_handle);
  $reports->limit(column => 'id', operator => '>', value => $self->_oid);
  $reports->order_by(column => 'id');

  while(my $report = $reports->next) {
    if ($report->total_failed || $report->total_unexpectedly_succeeded) {
      $self->{passing_projects}->{$report->project} = 0;
      my $msg =
        "Smoke report for " .  $report->project . " r" . $report->revision . " submitted: "
        . sprintf( "%.2f", $report->total_ratio * 100 ) . "\%, "
        . $report->total_seen . " total, "
        . $report->total_ok . " ok, "
        . $report->total_failed . " failed, "
        . $report->total_todo . " todo, "
        . $report->total_skipped . " skipped, "
        . $report->total_unexpectedly_succeeded . " unexpectedly succeeded.  "
        . $self->{server_script} . "?id=" . $report->id;

      $self->_say_to_all($msg);
    } else {
      if (! exists $self->{passing_projects}->{$report->project}) {
        # don't announce if we've never seen this project before
        $self->{passing_projects}->{$report->project} = 1;
      }
      next if $self->{passing_projects}->{$report->project};
      $self->{passing_projects}->{$report->project} = 1;
      
      $self->{passing_projects}->{$report->project}++;
      $self->_say_to_all("Smoke report for " .  $report->project
                         . " r" . $report->revision . " submitted: "
                         . "all " . $report->total_ok . " tests pass");
    }
  }

  my $last = $reports->last;
  if (defined $last) {
    # we might already be at the highest oid
    $self->{oid} = $last->id;
  }
  
  return 5;
}
  
sub _say_to_all {
  my $self = shift;
  my $msg = shift;

  $self->say(channel => $_, body => $msg)
    for (@{$self->{channels}});
}

1;