TAP::Parser::SourceHandler::File - Stream TAP from a text file.

Test-Harness documentation Contained in the Test-Harness distribution.

Index

Code Index:

NAME

Top

TAP::Parser::SourceHandler::File - Stream TAP from a text file.

VERSION

Top

Version 3.23

SYNOPSIS

Top

  use TAP::Parser::Source;
  use TAP::Parser::SourceHandler::File;

  my $source = TAP::Parser::Source->new->raw( \'file.tap' );
  $source->assemble_meta;

  my $class = 'TAP::Parser::SourceHandler::File';
  my $vote  = $class->can_handle( $source );
  my $iter  = $class->make_iterator( $source );

DESCRIPTION

Top

This is a raw TAP stored in a file TAP::Parser::SourceHandler - it has 2 jobs:

1. Figure out if the raw source it's given is a file containing raw TAP output. See TAP::Parser::IteratorFactory for more details.

2. Takes raw TAP from the text file given, and converts into an iterator.

Unless you're writing a plugin or subclassing TAP::Parser, you probably won't need to use this module directly.

METHODS

Top

Class Methods

can_handle

  my $vote = $class->can_handle( $source );

Only votes if $source looks like a regular file. Casts the following votes:

  0.9 if it's a .tap file
  0.9 if it has an extension matching any given in user config.

make_iterator

  my $iterator = $class->make_iterator( $source );

Returns a new TAP::Parser::Iterator::Stream for the source. croaks on error.

iterator_class

The class of iterator to use, override if you're sub-classing. Defaults to TAP::Parser::Iterator::Stream.

CONFIGURATION

Top

  {
   extensions => [ @case_insensitive_exts_to_match ]
  }

SUBCLASSING

Top

Please see SUBCLASSING in TAP::Parser for a subclassing overview.

SEE ALSO

Top

TAP::Object, TAP::Parser, TAP::Parser::SourceHandler, TAP::Parser::SourceHandler::Executable, TAP::Parser::SourceHandler::Perl, TAP::Parser::SourceHandler::Handle, TAP::Parser::SourceHandler::RawTAP

Test-Harness documentation Contained in the Test-Harness distribution. 
package TAP::Parser::SourceHandler::File;

use strict;
use vars qw($VERSION @ISA);

use TAP::Parser::SourceHandler    ();
use TAP::Parser::IteratorFactory  ();
use TAP::Parser::Iterator::Stream ();

@ISA = qw(TAP::Parser::SourceHandler);

TAP::Parser::IteratorFactory->register_handler(__PACKAGE__);


$VERSION = '3.23';


sub can_handle {
    my ( $class, $src ) = @_;
    my $meta   = $src->meta;
    my $config = $src->config_for($class);

    return 0 unless $meta->{is_file};
    my $file = $meta->{file};
    return 0.9 if $file->{lc_ext} eq '.tap';

    if ( my $exts = $config->{extensions} ) {
        return 0.9 if grep { lc($_) eq $file->{lc_ext} } @$exts;
    }

    return 0;
}


sub make_iterator {
    my ( $class, $source ) = @_;

    $class->_croak('$source->raw must be a scalar ref')
      unless $source->meta->{is_scalar};

    my $file = ${ $source->raw };
    my $fh;
    open( $fh, '<', $file )
      or $class->_croak("error opening TAP source file '$file': $!");
    return $class->iterator_class->new($fh);
}


use constant iterator_class => 'TAP::Parser::Iterator::Stream';

1;

__END__