Text::DHCPLeases - Parse DHCP leases file from ISC dhcpd.

    use Text::DHCPLeases;

    my $leases = Text::DHCPLeases->new("/etc/dhcpd.leases");

    foreach my $obj ( $leases->get_objects ){
        print $obj->name;
        if ( $obj->binding_state eq 'active' ){
           ...
    }
    ...

  Arguments:
    Hash with the following keys:
    file  -  Leases file path
  Returns:
    Text::DHCPLeases object
  Examples:
    Text::DHCPLeases->new(file=>"/etc/dhcpd.leases");
=cut

  Arguments:
    Object attributes to match (optional)
  Returns:
    Array of Text::DHCPLeases::Lease objects, 
    or iterator depending on context.  
  Examples:
    my $it = $leases->get_objects(ip_address=>'192.168.0.1');
    while ( my $obj = $it->next ) ...
=cut

  Arguments:
    None
  Returns:
    Formatted String
  Examples:
    print $leases->print;
=cut

package Text::DHCPLeases;

use warnings;
use strict;
use Carp;
use Text::DHCPLeases::Object;
use Text::DHCPLeases::Object::Iterator;
use vars qw($VERSION);
$VERSION = '0.9';

my $IPV4  = '\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}';

# Make sure to return 1
1;

############################################################

sub new{
    my ($proto, %argv) = @_;
    croak "Missing required parameters: file" unless defined $argv{file};
    my $class = ref($proto) || $proto;
    my $self = {};
    bless $self, $class;
    $self->{_objects} = $self->_parse($argv{file});
    return $self;
}

############################################################

sub get_objects{
    my ($self, %argv) = @_;
    my @list;
    if ( %argv ){
	foreach my $obj ( @{$self->{_objects}} ){
	    my $match = 1;
	    foreach my $key ( keys %argv ){
		if ( !defined $obj->$key || $obj->$key ne $argv{$key} ){
		    $match = 0;
		    last;
		}
	    }
	    push @list, $obj if $match;
	}
    }else{
	# Use 'all' array to get real order from file
	@list = @{$self->{_objects}};
    }
    wantarray? @list : DHCPLeases::Object::Iterator->new(\@list);
}

############################################################

sub print{
    my ($self) = @_;
    my $out = "";
    foreach my $obj ( $self->get_objects ){
	$out .= $obj->print;
    }
    return $out;
}

############################################################
#
# ********* PRIVATE METHODS **********
#
############################################################


############################################################
# _parse - Populate array of objects after reading file
#
# Arguments:
#    filename
# Returns:
#    Hash reference.  
#    Key:   declaration header
#    Value: reference to array with all objects
#
sub _parse {
    my ($self, $file) = @_;
    my @objects;
    my $declist = $self->_get_decl($file);
    foreach my $decl ( @$declist ){
	my $header = $decl->{header};
	my $lines  = $decl->{lines};
	my $obj;
	if ( $header =~ /^(lease|host|group|subgroup|failover peer)/ ){
	    my $obj_data = Text::DHCPLeases::Object->parse($lines);
	    $obj = Text::DHCPLeases::Object->new(%$obj_data);
	    push @objects, $obj;	
	}else{
	    croak "Text::DHCPLeases::_parse Error: Declaration header not recognized: $header\n";
	}
    }
    return \@objects;
}

############################################################
# _get_decl - Parse file and return all declarations
#
# Arguments:
#    filename
# Returns:
#    Array ref of hashrefs.  
#    
sub _get_decl {
    my ($self, $file) = @_;
    open(FILE, "<$file") or croak "Can't open file $file: $!\n";
    my @list;
    my $lines = [];
    my $header;
    my $open = 0;
    my $decl;
    while ( <FILE> ){
	my $line = $_;
	$line =~ s/^\s*(.*)\s*$/$1/;
	next if ( $line =~ /^#|^$/ );
	if ( !$open && $line =~ /^(.*) \{$/ ){
	    $decl = {};
	    $header = $1;
	    $decl->{header} = $header;
  	    $open   = 1;
	    $lines  = [];
	    push @$lines, $line;
	    next;
	}
	if ( $open ){
	    if ( $line =~ /^\}$/ ){
		$open = 0;
		$decl->{lines}  = $lines;
		push @list, $decl;
		$header = "";
		push @$lines, $line;
	    }else{
		push @$lines, $line;
	    }
	}
    }
    close(FILE);
    return \@list;
}