Tripletail::Sendmail - Tripletail::Sendmail documentation

  my $sendmail = $TL->newSendmail
    ->connect
    ->send(
        -from => 'null@example.org',
	-rcpt => 'null@example.org',
	-data => '.....',
       )
    ->disconnect;

# -----------------------------------------------------------------------------
# Tripletail::Sendmail - メールの送信を行う
# -----------------------------------------------------------------------------
package Tripletail::Sendmail;
use strict;
use warnings;
use Tripletail;

1;

sub _new {
	my $class = shift;
	my $group = shift;

	$group = defined $group ? $group : 'Sendmail';

	# iniのmethodパラメータに応じて実際のクラスのインスタンスを作る。
	my $method = $TL->INI->get($group => 'method');
	if(!defined($method)) {
		$method = 'smtp';
	}

	if($method eq 'smtp') {
		require Tripletail::Sendmail::Smtp;
		Tripletail::Sendmail::Smtp->_new($group);
	} elsif($method eq 'sendmail') {
		require Tripletail::Sendmail::Sendmail;
		Tripletail::Sendmail::Sendmail->_new($group);
	} elsif($method eq 'mailqueue') {
		require Tripletail::Sendmail::MailQueue;
		Tripletail::Sendmail::MailQueue->_new($group);
	} elsif($method eq 'esmtp') {
		require Tripletail::Sendmail::Esmtp;
		Tripletail::Sendmail::Esmtp->_new($group);
	} else {
		die "TL#newSendmail: unknown method [$method] is defined for the INI group [$group]. (Iniファイルのmethodの指定が不正です)\n";
	}
}

sub setTimeout {
	# デフォルトの実装では何もしない
    shift;
}

sub connect {
	# デフォルトの実装では何もしない
    shift;
}

sub disconnect {
	# デフォルトの実装では何もしない
    shift;
}

sub send {
	# オーバーライドしなければエラー
	die __PACKAGE__."#send: internal error: this method has to be overridden. (内部エラー:このメソッドはオーバーライドされなければなりません)\n";
}

sub _setLogging {
	# デフォルトの実装では何もしない
	# TL内部でのエラー処理用に、ログ保存のオプションを変更したいときに呼び出される。
	# iniファイルのloggingよりこちらの指定を優先しなければならない。
    shift;
}

sub _getoptSend {
	my $this = shift;
	my $pkg = ref($this);

	my $data = do {
		my %hash = @_;
		%hash = map {
			my $key = $_;
			my $val = $hash{$key};

			$key =~ s/^-//;
			$key => $val;
		} keys %hash;
			\%hash;
	};

	if(!defined($data->{data})) {
		die "$pkg#send: arg[data] is not defined. (dataが指定されていません)\n";
	}

	if(!defined($data->{from}) || !defined($data->{rcpt})) {
		# 省略されているので本文から読み出す

		local *addr = sub {
			my $str = shift;
			defined $str or return undef;

			$str =~ s/^\s*|\s*$//g;

			if($str =~ m/<(.+?)>\s*$/) {
				$1;
			} else {
				$str;
			}
		};

		my $mail = $TL->newMail->set($data->{data});
		$data->{from} = addr($mail->getHeader('From'));
		$data->{rcpt} = addr($mail->getHeader('to'));
	}

	if(!defined($data->{from})) {
		die "$pkg#send: arg[from] is undef but the data don't have a valid `From' header. (fromが指定されておらず、dataからも推測できません)\n";
	}
	if(!defined($data->{rcpt})) {
		die "$pkg#send: arg[rcpt] is undef but the data don't have a valid `To' header. (rcptが指定されておらず、dataからも推測できません)\n";
	}

	if(ref($data->{rcpt}) ne 'ARRAY') {
		$data->{rcpt} = [ $data->{rcpt} ];
	}

	$data;
}


__END__