VCS::LibCVS::FileBranch - A specific branch of a file managed by CVS.

  VCS::LibCVS

#
# Copyright (c) 2003,2004,2005 Alexander Taler (dissent@0--0.org)
#
# All rights reserved. This program is free software; you can redistribute it
# and/or modify it under the same terms as Perl itself.
#

package VCS::LibCVS::FileBranch;

use strict;
use Carp;

###############################################################################
# Class constants
###############################################################################

use constant REVISION => '$Header: /cvsroot/libcvs-perl/libcvs-perl/VCS/LibCVS/FileBranch.pm,v 1.13 2005/10/10 12:52:11 dissent Exp $ ';

###############################################################################
# Class variables
###############################################################################

###############################################################################
# Private variables
###############################################################################

# $self->{File}            VCS::LibCVS::RepositoryFile of this FileBranch
# $self->{TagSpec}         VCS::LibCVS::Datum::TagSpec of the FileBranch
#                          It's undef for the main branch/trunk
# $self->{RevisionNumber}  VCS::LibCVS::Datum::RevisionNumber of this FileBranch

###############################################################################
# Class routines
###############################################################################

sub new {
  my $class = shift;
  my $that = bless {}, $class;

  ($that->{File}, $that->{TagSpec}, $that->{RevisionNumber}) = @_;

  return $that;
}

###############################################################################
# Instance routines
###############################################################################

sub get_revision_number() {
  return shift->{RevisionNumber};
}

sub get_file() {
  return shift->{File};
}

sub get_tag() {
  return shift->{TagSpec};
}

sub get_tip_revision() {
  my $self = shift;
  my $log = $self->{File}->_get_log_messages();

  # The log messages are an indication of all the revisions of the file.  We go
  # through them all, and find the latest one on this branch
  my $tip_num = $self->{RevisionNumber};
  foreach my $rev_str (keys %$log) {
    my $rev = VCS::LibCVS::Datum::RevisionNumber->new($rev_str);
    # Only compare revision numbers on this branch.
    if ($rev->branch_of()->equals($self->{RevisionNumber})) {
      if (   $tip_num->compare($rev)
          == VCS::LibCVS::Datum::RevisionNumber::COMPARE_DESCENDANT) {
        $tip_num = $rev;
      }
    }
  }
  return VCS::LibCVS::FileRevision->new($self->{File}, $tip_num);
}

sub get_first_revision() {
  my $self = shift;

  if ($self->is_trunk()) {
    my $first_rev = $self->{RevisionNumber}->first_revision_of();
    return VCS::LibCVS::FileRevision->new($self->{File}, $first_rev);
  } else {
    return VCS::LibCVS::FileRevision->new($self->{File},
                                          $self->{RevisionNumber}->base_of(),
                                          $self->{RevisionNumber});
  }
}

sub get_revision() {
  my $self = shift;
  my $time = shift;

  confess "Predictions of the future not yet supported." if ($time > time);

  # Traverse the revisions on the branch and return at the end of the branch or
  # when a revision was committed after time.  $best_rev is what we return, and
  # is always a revision committed before the time.  If the branch was created
  # after time, then we return undef.
  my $best_rev;
  my $next_rev = $self->get_first_revision();
  while ((defined $next_rev) && ($next_rev->get_time() < $time)) {
    $best_rev = $next_rev;
    $next_rev = $next_rev->get_successor();
  }
  return $best_rev;
}

sub get_branch() {
  my $self = shift;

  return VCS::LibCVS::Branch->new($self->{File}->get_repository(),
                                  $self->{TagSpec}->get_name());
}

sub is_trunk {
  return shift->{RevisionNumber}->is_trunk();
}

sub get_parent() {
  my $self = shift;
  return $self->{File}->get_branch($self->{RevisionNumber}->base_of()->branch_of());
}

sub equals() {
  my $self = shift;
  my $other = shift;

  if (! $other->isa("VCS::LibCVS::FileBranch")) {
    return 0;
  }

  return (($self->{File}->equals($other->{File})) &&
          ($self->{TagSpec}->equals($other->{TagSpec})) &&
          ($self->{RevisionNumber}->equals($other->{RevisionNumber})));
}

sub precedes() {
  my $self = shift;
  my $other = shift;

  if (! $other->isa("VCS::LibCVS::FileBranch")) {
    confess("Not a FileBranch");
  }

  if (! $self->{File}->equals($other->{File})) {
    confess "precedes() only works on FileBranches of the same File.";
  }

  my $cmp = $self->{RevisionNumber}->compare($other->{RevisionNumber});

  return ($cmp == VCS::LibCVS::Datum::RevisionNumber::COMPARE_DESCENDANT) ||
    ($cmp == VCS::LibCVS::Datum::RevisionNumber::COMPARE_POSSIBLE_DESCENDANT);
}

###############################################################################
# Private routines
###############################################################################

1;