WWW::FreshMeat::API::Pub - FreshMeats published / public (take your pick!) API methods

    use Moose;

    with 'WWW::FreshMeat::API::Pub';

    perldoc WWW::FreshMeat::API::Pub

package WWW::FreshMeat::API::Pub;
use Moose::Role;
use WWW::FreshMeat::API::Pub::V1_03 qw/get_api_info/;

our $VERSION = '0.01';

#requires 'sid';

sub BUILD {
    my $self = shift;
    my $api  = get_api_info();
    
    for my $name ( keys %{ $api } ) {
        
        # if mock then setup some dummy methods
        if ( $self->mock ) {
            $self->meta->add_method( $name => sub {
                my ( $self, %params ) = @_;
                return $api->{ $name }->{ returns };
            });
            next;
        }
         
        # else public methods... however next two require setting up session
        next  if $name eq 'login';
        next  if $name eq 'logout';
        
        # now all remaining public methods - v1.03
        if ( @{ $api->{ $name }->{ params } } ) {
            
            # build methods with params
            $self->meta->add_method( $name => sub {
                my ( $self, %params ) = @_;
                
                # add SID if it needs it (must be first in array)
                %params = ( SID => $self->session->{ SID }, %params )
                    if  $api->{ $name }->{ params }->[0] eq 'SID';
                    
                $self->agent->call( $name, \%params );
            });
        }
        
        else {
            # build method with no params
            $self->meta->add_method( $name => sub {
                my $self = shift;
                $self->agent->call( $name );
            });
        }
    }   
}

# session methods
sub login {
    my ( $self, %params ) = @_;
    $self->session( $self->agent->call( 'login', \%params ) );
}

sub logout {
    my $self = shift;
    $self->agent->call( 'logout', { SID => $self->session->{ SID } } );
    $self->clear_session;
}

no Moose::Role;

1;


__END__