WWW::Ohloh::API::Kudo - an Ohloh kudo

WWW-Ohloh-API documentation Contained in the WWW-Ohloh-API distribution.

Index

Code Index:

NAME

Top

WWW::Ohloh::API::Kudo - an Ohloh kudo

SYNOPSIS

Top

    use WWW::Ohloh::API;

    my $ohloh    = WWW::Ohloh::API->new( api_key => $my_api_key );
    my $account  = $ohloh->get_account( id => 12933 );
    my @received = $account->received_kudos;

    # or, from $ohloh directly
    my @sent = $ohloh->get_kudos( id => 12933 )->sent;

DESCRIPTION

Top

W::O::A::Kudo contains the information associated with an Ohloh kudo as defined at http://www.ohloh.net/api/reference/kudo. To be properly populated, it must be created via the get_kudos method of a WWW::Ohloh::API object, or via the received_kudos/sent_kudos methods of a WWW::Ohloh::API::Account object.

METHODS

Top

API Data Accessors

created_at

Return the kudo's creation time.

sender_account_id, sender_account_name

Return the id/name of the account sending the kudo.

receiver_account_id, receiver_account_name

Return the id/name associated with the account that received the kudo, or an empty string if the kudo couldn't be linked to an account.

project_id, project_name

Return the project id/name if the kudo was sent to a project contributor instead than an account, or an empty string otherwise.

contributor_id, contributor_name

Return the cotnributor's id/name if the kudo was sent to a project contributor instead than an account, or an empty string otherwise.

Other Methods

as_xml

Return the kudo information as an XML string. Note that this is not the exact xml document as returned by the Ohloh server.

SEE ALSO

Top

*

WWW::Ohloh::API, WWW::Ohloh::API::Kudos, WWW::Ohloh::API::KudoScore.

*

Ohloh API reference: http://www.ohloh.net/api/getting_started

*

Ohloh Account API reference: http://www.ohloh.net/api/reference/kudo

VERSION

Top

This document describes WWW::Ohloh::API version 0.3.1

BUGS AND LIMITATIONS

Top

WWW::Ohloh::API is very extremely alpha quality. It'll improve, but till then: Caveat emptor.

The as_xml() method returns a re-encoding of the account data, which can differ of the original xml document sent by the Ohloh server.

Please report any bugs or feature requests to bug-www-ohloh-api@rt.cpan.org, or through the web interface at http://rt.cpan.org.

AUTHOR

Top

Yanick Champoux <yanick@cpan.org>

LICENCE AND COPYRIGHT

Top

Copyright (c) 2008, Yanick Champoux <yanick@cpan.org>. All rights reserved.

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself. See perlartistic.

WWW-Ohloh-API documentation Contained in the WWW-Ohloh-API distribution. 
package WWW::Ohloh::API::Kudo;

use strict;
use warnings;

use Carp;
use Object::InsideOut;
use XML::LibXML;
use WWW::Ohloh::API::KudoScore;

our $VERSION = '0.3.1';

my @api_fields = qw/
  created_at
  sender_account_id
  sender_account_name
  receiver_account_name
  receiver_account_id
  project_id
  project_name
  contributor_id
  contributor_name
  /;

my @created_at_of : Field : Set(_set_created_at) : Get(created_at);
my @sender_account_id_of : Field : Set(_set_sender_account_id) :
  Get(sender_account_id);
my @sender_account_name_of : Field : Set(_set_sender_account_name) :
  Get(sender_account_name);
my @receiver_account_name_of : Field : Set(_set_receiver_account_name) :
  Get(receiver_account_name);
my @receiver_account_id_of : Field : Set(_set_receiver_account_id) :
  Get(receiver_account_id);
my @project_id_of : Field : Set(_set_project_id) : Get(project_id);
my @project_name_of : Field : Set(_set_project_name) : Get(project_name);
my @contributor_id_of : Field : Set(_set_contributor_id) :
  Get(contributor_id);
my @contributor_name_of : Field : Set(_set_contributor_name) :
  Get(contributor_name);

my @request_url_of : Field : Arg(request_url) : Get( request_url );
my @xml_of : Field : Arg(xml);
my @ohloh_of : Field : Arg(ohloh) : Get(_ohloh);

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub _init : Init {
    my $self = shift;

    my $dom = $xml_of[$$self] or return;

    $self->_set_created_at( $dom->findvalue("created_at/text()") );
    $self->_set_sender_account_id(
        $dom->findvalue("sender_account_id/text()") );
    $self->_set_sender_account_name(
        $dom->findvalue("sender_account_name/text()") );
    $self->_set_receiver_account_name(
        $dom->findvalue("receiver_account_name/text()") );
    $self->_set_receiver_account_id(
        $dom->findvalue("receiver_account_id/text()") );
    $self->_set_project_id( $dom->findvalue("project_id/text()") );
    $self->_set_project_name( $dom->findvalue("project_name/text()") );
    $self->_set_contributor_id( $dom->findvalue("contributor_id/text()") );
    $self->_set_contributor_name(
        $dom->findvalue("contributor_name/text()") );
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub recipient_type {
    my $self = shift;

    return $self->receiver_account_id ? 'account' : 'contributor';
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub sender {
    my $self = shift;

    return $self->_ohloh->get_account( id => $self->sender_account_id );
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub receiver {
    my $self = shift;

    if ( my $id = $self->receiver_account_id ) {
        return $self->_ohloh->get_account( id => $id );
    }

    return;
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub as_xml {
    my $self = shift;
    my $xml;
    my $w = XML::Writer->new( OUTPUT => \$xml );

    $w->startTag('kudo');
    for my $e (@api_fields) {
        $w->dataElement( $e => $self->$e ) if $self->$e;
    }

    $w->endTag;

    return $xml;
}

'end of WWW::Ohloh::API::Kudo';
__END__