WWW::Scraper::ISBN::Pearson_Driver - Search driver for the Pearson Education online book catalog.

WWW-Scraper-ISBN-Pearson_Driver documentation Contained in the WWW-Scraper-ISBN-Pearson_Driver distribution.

Index

Code Index:

NAME

Top

WWW::Scraper::ISBN::Pearson_Driver - Search driver for the Pearson Education online book catalog.

SYNOPSIS

Top

See parent class documentation (WWW::Scraper::ISBN::Driver)

DESCRIPTION

Top

Searches for book information from the Pearson Education's online catalog.

METHODS

Top

search()

Creates a query string, then passes the appropriate form fields to the Pearson Education server.

The returned page should be the correct catalog page for that ISBN. If not the function returns zero and allows the next driver in the chain to have a go. If a valid page is returned, the following fields are returned via the book hash:

  isbn          (now returns isbn13)
  isbn10        
  isbn13
  ean13         (industry name)
  author
  title
  book_link
  image_link
  description
  pubdate
  publisher
  binding       (if known)
  pages         (if known)
  weight        (if known) (in grammes)
  width         (if known) (in millimetres)
  height        (if known) (in millimetres)

The book_link and image_link refer back to the Pearson Education UK website.

REQUIRES

Top

Requires the following modules be installed:

WWW::Scraper::ISBN::Driver, WWW::Mechanize

SEE ALSO

Top

WWW::Scraper::ISBN, WWW::Scraper::ISBN::Record, WWW::Scraper::ISBN::Driver

BUGS, PATCHES & FIXES

Top

There are no known bugs at the time of this release. However, if you spot a bug or are experiencing difficulties that are not explained within the POD documentation, please send an email to barbie@cpan.org or submit a bug to the RT system (http://rt.cpan.org/Public/Dist/Display.html?Name=WWW-Scraper-ISBN-Pearson_Driver). However, it would help greatly if you are able to pinpoint problems or even supply a patch.

Fixes are dependant upon their severity and my availablity. Should a fix not be forthcoming, please feel free to (politely) remind me.

AUTHOR

Top

  Barbie, <barbie@cpan.org>
  Miss Barbell Productions, <http://www.missbarbell.co.uk/>

COPYRIGHT & LICENSE

Top

  Copyright (C) 2004-2011 Barbie for Miss Barbell Productions

  This module is free software; you can redistribute it and/or
  modify it under the Artistic Licence v2.
WWW-Scraper-ISBN-Pearson_Driver documentation Contained in the WWW-Scraper-ISBN-Pearson_Driver distribution. 
package WWW::Scraper::ISBN::Pearson_Driver;

use strict;
use warnings;

use vars qw($VERSION @ISA);
$VERSION = '0.18';

#--------------------------------------------------------------------------


#--------------------------------------------------------------------------

###########################################################################
# Inheritence

use base qw(WWW::Scraper::ISBN::Driver);

###########################################################################
# Modules

use WWW::Mechanize;

###########################################################################
# Constants

use constant	SEARCH	=> 'http://www.pearsoned.co.uk/Bookshop/';
use constant	DETAIL	=> 'http://www.pearsoned.co.uk/Bookshop/detail.asp?item=';

#--------------------------------------------------------------------------

###########################################################################
# Public Interface


sub search {
	my $self = shift;
	my $isbn = shift;
	$self->found(0);
	$self->book(undef);

	my $mech = WWW::Mechanize->new();
    $mech->agent_alias( 'Linux Mozilla' );

	eval { $mech->get( SEARCH ) };
    return $self->handler("Pearson Education website appears to be unavailable.")
	    if($@ || !$mech->success() || !$mech->content());

	$mech->form_id('frmSearch');
	$mech->set_fields( 'txtSearch' => $isbn );
	
    eval { $mech->submit() };
	return $self->handler("Failed to find that book on Pearson Education website.")
	    if($@ || !$mech->success() || !$mech->content());

	# The Book page
    my $html = $mech->content();
#print STDERR "\n# content1=[\n$html\n]\n";

	return $self->handler("Failed to find that book on Pearson Education website.")
		if($html =~ m!<p>Your search for <b>\d+</b> returned 0 results. Please search again.</p>!si);

    my $data;
    ($data->{image},$data->{thumb})     = $html =~ m!<a id="large-jacket-img" href="(http://images.pearsoned-ema.com/jpeg/[^"]+)"><img src="(http://images.pearsoned-ema.com/jpeg/[^"]+)"!si;
    ($data->{title})                    = $html =~ m!<div class="biblio">\s*<h1 class="larger bold">(.*?)</h1>!si;
    ($data->{author},$data->{pubdate},$data->{binding},$data->{pages}) 
                                        = $html =~ m!<h2 class="body"><a title=[^>]+>(.*?)</a></h2>([^,]+),\s*([^,<]+)(?:,\s*([^<]+)pages)?<br />!si;
    ($data->{isbn13},$data->{isbn10})   = $html =~ m!ISBN13:\s*(\d+)\s*<br />ISBN10:\s*(\d+)!si;
    ($data->{description})              = $html =~ m!<div class="desc-text"><p><p>([^<]+)!is;
    ($data->{bookid})                   = $html =~ m!recommend.asp\?item=(\d+)!si;

#use Data::Dumper;
#print STDERR "\n# " . Dumper($data);

	return $self->handler("Could not extract data from Pearson Education result page.")
		unless(defined $data);

	# trim top and tail
	foreach (keys %$data) { next unless(defined $data->{$_});$data->{$_} =~ s/^\s+//;$data->{$_} =~ s/\s+$//; }

	my $bk = {
		'ean13'		    => $data->{isbn13},
		'isbn13'		=> $data->{isbn13},
		'isbn10'		=> $data->{isbn10},
		'isbn'			=> $data->{isbn13},
		'author'		=> $data->{author},
		'title'			=> $data->{title},
		'book_link'		=> $mech->uri(),   #DETAIL . $data->{bookid},
		'image_link'	=> $data->{image},
		'thumb_link'	=> $data->{thumb},
		'description'	=> $data->{description},
		'pubdate'		=> $data->{pubdate},
		'publisher'		=> q!Pearson Education!,
		'binding'	    => $data->{binding},
		'pages'		    => $data->{pages},
		'weight'		=> $data->{weight},
		'width'		    => $data->{width},
		'height'		=> $data->{height}
	};

#use Data::Dumper;
#print STDERR "\n# book=".Dumper($bk);

    $self->book($bk);
	$self->found(1);
	return $self->book;
}

1;
__END__