WWW::TarPipe - An interface to tarpipe.com's REST based web service.

WWW-TarPipe documentation Contained in the WWW-TarPipe distribution.

Index

Code Index:

NAME

Top

WWW::TarPipe - An interface to tarpipe.com's REST based web service.

VERSION

Top

This document describes WWW::TarPipe version 0.01

SYNOPSIS

Top

    use WWW::TarPipe;

    my $tp = WWW::TarPipe->new( 
        key => '77c38f56696963fa13f5b6cd97a2556c' 
    );

    $tp->upload( 
        title => 'The outside temperature is 27C' 
    );

DESCRIPTION

Top

tarpipe.com is a publishing mediation and distribution platform that simplifies regular upload activities:

* Publishing content to multiple Web locations;
* Combining different media into a single blog post or article;
* Transforming documents on-the-fly;
* Managing repeatable upload actions.

You can learn more by visiting http://tarpipe.com/.

INTERFACE

Top

new

Create a new WWW::TarPipe. Accepts a number of key, value pairs. The following arguments are recognised:

base_uri

The base URI for the tarpit REST service. Defaults to

    http://rest.receptor.tarpipe.net:8000/
title

The title of the data being posted.

body

A larger chunk of text associated with this post such as a blog post.

image

A chunk of binary data - perhaps an image - for this post.

key

The token generated when you save a REST API workflow.

Any options not passed to new may be passed to a subsequent call to upload, for example:

    my $tp = WWW::TarPipe->new( 
        key => '77c38f56696963fa13f5b6cd97a2556c' 
    );

    $tp->upload( 
        title => 'The outside temperature is 27C' 
    );

is equivalent to

    my $tp = WWW::TarPipe->new;

    $tp->upload( 
        key   => '77c38f56696963fa13f5b6cd97a2556c', 
        title => 'The outside temperature is 27C' 
    );

When making multiple posts to the same workflow it is convenient to supply unchanging options as arguments to new and pass those that change to upload.

upload

Send an upload request to the tarpit.com REST service. A number of key, value argument pairs should be passed. See new above for details of the arguments that can be specified.

    $tp->upload( 
        key   => '77c38f56696963fa13f5b6cd97a2556c',
        title => 'Hello, World',
        body  => "First Post!\nYay me!\n"
    );

If the request fails an exception will be thrown.

Accessors

Each of the options that may be supplied to new and upload have a corresponding read only accessor.

base_uri

The base URI for the tarput service.

title

The title of the post.

body

The body of the post.

image

Arbitrary image data.

key

The REST key for the workflow.

default_base_uri

Returns the default URI for the tarpipe service. May be overridden in subclasses or by supplying the base_uri option to new or upload.

CONFIGURATION AND ENVIRONMENT

Top

WWW::TarPipe requires no configuration files or environment variables.

DEPENDENCIES

Top

None.

INCOMPATIBILITIES

Top

None reported.

BUGS AND LIMITATIONS

Top

No bugs have been reported.

Please report any bugs or feature requests to bug-www-tarpipe@rt.cpan.org, or through the web interface at http://rt.cpan.org.

AUTHOR

Top

Andy Armstrong <andy@hexten.net>

LICENCE AND COPYRIGHT

Top

Copyright (c) 2008, Andy Armstrong <andy@hexten.net>.

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself. See perlartistic.

WWW-TarPipe documentation Contained in the WWW-TarPipe distribution. 
package WWW::TarPipe;

use warnings;
use strict;
use Carp;
use LWP::UserAgent;


our $VERSION = '0.01';

my @ATTR;

BEGIN {
    @ATTR = qw(
      base_uri body image key title
    );

    for my $attr ( @ATTR ) {
        no strict 'refs';
        *$attr = sub {
            my $self = shift;
            croak "$attr may not be set" if @_;
            return $self->{$attr};
        };
    }
}


sub new {
    my $class = shift;
    return bless {
        base_uri => $class->default_base_uri,
        $class->_check_args( @_ )
    }, $class;
}


sub upload {
    my $self = shift;
    my %args = ( %$self, $self->_check_args( @_ ) );
    my $ua   = LWP::UserAgent->new;

    my $uri = delete $args{base_uri}
      or croak "base_uri must be supplied";
    my $key = delete $args{key}
      or croak "key must be supplied";

    my $resp = $ua->post(
        "$uri?key=$key",
        Content_Type => 'form-data',
        Content      => \%args
    );

    croak $resp->status_line if $resp->is_error;
    return $resp->content;

}

sub _check_args {
    my $self = shift;
    croak "Please supply a number of key, value pairs"
      if @_ % 1;
    my %args = @_;
    my %got  = ();

    for my $attr ( @ATTR ) {
        $got{$attr} = delete $args{$attr}
          if exists $args{$attr};
    }

    croak "Invalid options: ", join ', ', sort keys %args if keys %args;
    return %got;
}


sub default_base_uri { 'http://rest.receptor.tarpipe.net:8000/' }

1;

__END__