WWW::Twitpic::API - Twitpic simple API

    use WWW::Twitpic::API;

    my $client = WWW::Twitpic::API->new(
        username => 'a twitter username',
        password => 'the big secret'
    );

    # post a new image to the twitter feed
    $clent->post( '/path/to/image_filename' => 'The message for this pic' );

    # or just upload the image to twitpic
    $client->upload( '/path/to/image_filename' );

    Upload the provided image to twitpic.com

    Returns WWW::Twitpic::API::Response

    Example: $api->upload( '/tmp/my_picture.jpg' );

    See L<http://twitpic.com/api.do#upload>

    Upload the provided image to twitpic.com and post it
    on the username twitter feed with the optional
    message provided.

    Returns WWW::Twitpic::API::Response

    Example: $api->post( '/tmp/my_picture.jpg' => "Look ma, I'm on twitter!");

    See L<http://twitpic.com/api.do#uploadAndPost>

    Create and POST a request and return a Twitpic::API::Response.

    perldoc WWW::Twitpic

package WWW::Twitpic::API;
use Moose;
use Moose::Util::TypeConstraints;

use LWP::UserAgent;
use HTTP::Request::Common;
use URI;

use WWW::Twitpic::API::Response;

our $VERSION = '0.01';

coerce 'WWW::Twitpic::API::Response'
    => from 'Str'
     => via { WWW::Twitpic::API::Response->new( xml => $_ ) };

has 'username' => (
    is      => 'rw',
    isa     => 'Str'
);

has 'password' => (
    is      => 'rw',
    isa     => 'Str'
);

has 'ua' => (
    is      => 'rw',
    isa     => 'LWP::UserAgent',
    lazy    => 1,
    default => sub { LWP::UserAgent->new() }
);

has 'uri' => (
    is      => 'rw',
    isa     => 'URI',
    default => sub { URI->new('http://twitpic.com') }
);

has 'response' => (
    is        => 'rw',
    isa       => 'WWW::Twitpic::API::Response',
    predicate => 'has_response',
    coerce    => 1
);

sub upload {
    my ( $self, $file ) = @_; 

    $self->_make_request({ 
        path  => '/api/upload',
        media => [ $file ] 
    });
}

sub post {
    my ( $self, $file, $message ) = @_; 

    $self->_make_request({ 
        path  => '/api/uploadAndPost',
        media   => [ $file ],
        message => $message
    });
}

sub _make_request {
    my ( $self, $args ) = @_;

    my $url = $self->uri->clone;
    if ( my $path = delete $args->{path} ) {
        $url->path( $path );
    }
    else { confess 'We need a path to make a request' }

    my $res = $self->ua->request(
        POST(
            $url,
            Content_Type => 'form-data',
            Content      => [ 
                username => $self->username,
                password => $self->password,
                %$args
            ]
        )
    );

    if ( $res->is_success ) {
        $self->response( $res->content );
        return $self->response;
    }
    else {
        confess "Can't post to the server: " . $res->status_line;
    }
}

1;