WWW::Twitpic::API::Response - A response from Twitpic

    Boolean flag to check the response status.

    You can check the error() message when false. 

    Returns the error message if any.

    The id asigned to the uploaded image.

    The URI for the uploaded image.

    The URI of the generated thumbnail for the uploaded image.

    The URI of the generated mini-view for the uploaded image.

    The response xml source.

    The respnse href struct.

    Helper method to generate rezize uri's

    perldoc WWW::Twitpic

package WWW::Twitpic::API::Response;
use Moose;

use XML::Simple qw( XMLin );

has 'xml' => (
    is      => 'rw',
    isa     => 'Str',
    trigger => sub { $_[0]->struct( XMLin( $_[1] ) ) }
);

has 'struct' => (
    is        => 'rw',
    isa       => 'HashRef',
);

sub is_success {
    my $self = shift; 
    
    if ( my $status = $self->struct->{'status'} || $self->struct->{'stat'} ) {
        return $status eq 'ok';
    }
    return 0;
}

sub error {
    my $self = shift; 

    unless ( $self->is_success ) {
        if ( exists $self->struct->{'err'}{msg} ) {
            return $self->struct->{'err'}{msg};
        }
    }

    return undef;
}

sub id {
    my $self = shift;
    
    return $self->is_success ? $self->struct->{mediaid} : undef; 
}

sub url {
    my $self = shift;
    
    return $self->is_success ? URI->new( $self->struct->{mediaurl} ) : undef; 
}

sub url_thumb { $_[0]->_resize_uri('thumb'); }

sub url_mini  { $_[0]->_resize_uri('mini'); }

sub _resize_uri {
    my ( $self, $size ) = @_;
    $size ||= 'thumb';

    return $self->is_success
        ? URI->new( 'http://twitpic.com/show/' . $size . '/' . $self->id )
        : undef;
}

1;