XML::APML::ExplicitData - ExplicitData markup

XML-APML documentation Contained in the XML-APML distribution.

Index

Code Index:

NAME

Top

XML::APML::ExplicitData - ExplicitData markup

SYNOPSIS

Top

DESCRIPTION

Top

Class that represents ExplicitData mark-up for APML

METHODS

Top

new

Constructor

concepts

Get all concepts. Returns as array in list context.

    my @concepts = $explicit->concepts;

Or returns as array reference.

    my $concepts = $explicit->concepts;

Also, you can set multiple concepts at once.

    $explicit->concepts($concept1, $concept2, $concept3);

add_concept

Add concept

    $explicit->add_concept($concept);

sources

Get all sources. Returns as array in list context.

    my @sources = $explicit->sources;

Or returns as array reference.

    my $sources = $explicit->sources;

Also, you can set multiple sources at once.

    $explicit->sources($source1, $source2, $source3);

add_source

Add source

    $explicit->add_source($source);
XML-APML documentation Contained in the XML-APML distribution. 
package XML::APML::ExplicitData;

use strict;
use warnings;

use XML::APML::Concept;
use XML::APML::Source;

use base 'Class::Data::Accessor';

__PACKAGE__->mk_classaccessor( tag_name => 'ExplicitData' );
__PACKAGE__->mk_classaccessor( is_implicit => 0 );


sub new {
    my $class = shift;
    bless {
        concepts => [],
        sources  => [],
    }, $class;
}


sub concepts {
    my $self = shift;
    $self->add_concept($_) for @_;
    return wantarray ? @{ $self->{concepts} } : $self->{concepts};
}


sub add_concept {
    my ($self, $concept) = @_;
    push @{ $self->{concepts} }, $concept;
}


sub sources {
    my $self = shift;
    $self->add_source($_) for @_;
    return wantarray ? @{ $self->{sources} } : $self->{sources};
}


sub add_source {
    my ($self, $source) = @_;
    push @{ $self->{sources} }, $source;
}

sub parse_node {
    my ($class, $node) = @_;
    my $data = $class->new;
    my @concepts = $node->findnodes('*[local-name()=\'Concepts\']/*[local-name()=\'Concept\']');
    $data->add_concept(XML::APML::Concept->parse_node($_, $class->is_implicit)) for @concepts;
    my @sources = $node->findnodes('*[local-name()=\'Sources\']/*[local-name()=\'Source\']');
    $data->add_source(XML::APML::Source->parse_node($_, $class->is_implicit)) for @sources;
    $data;
}

sub build_dom {
    my ($self, $doc) = @_;
    my $class = ref $self;
    my $elem = $doc->createElement($class->tag_name);
    my $concepts = $doc->createElement('Concepts');
    for my $concept ( @{ $self->{concepts} } ) {
        $concepts->appendChild($concept->build_dom($doc, $class->is_implicit));
    }
    $elem->appendChild($concepts);
    my $sources = $doc->createElement('Sources');
    for my $source ( @{ $self->{sources} } ) {
        $sources->appendChild($source->build_dom($doc, $class->is_implicit));
    }
    $elem->appendChild($sources);
    $elem;
}

1;