dtRdr - toplevel data/environment for dotReader

  dtRdr->init;

  my @dirs = dtRdr->plugin_dirs;

  dtRdr->_init_reloader

  dtRdr->_init_logger;

  dtRdr->init_app_dir(__FILE__); # must be next to data/

  dtRdr->set_user_dir($dirname);

  dtRdr->_init_user_dir;

  dtRdr->_reload;

  dtRdr->release_number;

  dtRdr->first_time;

  my $text = dtRdr->get_LICENSE;

  my $text = dtRdr->get_COPYING;

  dtRdr->_get_THIS('LICENSE|COPYING');

package dtRdr;
$VERSION = eval{require version}?version::qv($_):$_ for(0.11.2);

use dtRdr::0; # the rest of this package

use warnings;
use strict;
use Carp;

use dtRdr::Plugins;
use dtRdr::User;
use dtRdr::Logger;
use File::Copy ();

use Class::Accessor::Classy;
rs_c user     => \ (my $set_user) => '';
rw_c user_dir => './';
no  Class::Accessor::Classy;

use constant {
  home_page => 'http://localhost/',
};

my $reloader;
my $did_init = 0;

sub init {
  my $package = shift;

  # only run once
  if($did_init) {
    # Wouldn't be any reason to make noise, except if we start passing
    # parameters here, I better remind me to fix that. --Eric
    @_ and carp "cannot init";
    return;
  }
  $did_init = 1;

  $package->_init_logger;

  my $user = dtRdr::User->new();
  $user->init_config($package->user_dir . 'drconfig.yml');
  $package->$set_user($user);

  dtRdr::Plugins->init;
  $package->_init_reloader;

} # end subroutine init definition
########################################################################

sub plugin_dirs {
  my $package = shift;

  my @dirs;
  foreach my $spot (qw(data_dir user_dir)) {
    my $dirname = $package->$spot . 'plugins';
    push(@dirs, $dirname) if(-e $dirname);
  }
  return(@dirs);
} # end subroutine plugin_dirs definition
########################################################################

sub _init_reloader {
  my $package = shift;
  eval { require Module::Refresh };
  $@ and return;
  $reloader = Module::Refresh->new;
} # end subroutine _init_reloader definition
########################################################################

sub _init_logger {
  my $package = shift;
  my $config = $package->data_dir . 'log.conf';
  unless(-e $config) {
    (-e "$config.tmpl") or die "cannot find '$config' or '$config.tmpl'";
    File::Copy::copy("$config.tmpl", $config);
  }
  dtRdr::Logger->init(filename => $config);
} # end subroutine _init_logger definition
########################################################################

sub init_app_dir {
  my $package = shift;
  my ($filename) = @_;
  # TODO do we need an 'app_dir' accessor?

  my $app_dir = $package->program_dir($filename);

  $package->_init_user_dir;
} # end subroutine init_app_dir definition
########################################################################

sub set_user_dir {
  my $package = shift;
  my ($dir) = @_;
  $dir =~ s#\\#/#g if($^O eq 'MSWin32');
  $dir ||= './';
  $dir =~ s#/*$#/#;
  $package->SUPER::set_user_dir($dir);
} # end subroutine set_user_dir definition
########################################################################

# This might want to go live in the dtRdr::User object instead.

my $did_init_user_dir = 0;
sub _init_user_dir {
  my $package = shift;

  # only DWIM once
  $did_init_user_dir and return;
  $did_init_user_dir = 1;

  if(my $dir = $ENV{DOTREADER_USER_DIR}) {
    return $package->set_user_dir($dir);
  }

  # TODO check ~/.dotreader and such

  my $loc = $package->program_base . '-data';
  unless(-d $loc) { L->warn("no $loc"); return; }

  $package->set_user_dir($loc);
} # end subroutine _init_user_dir definition
########################################################################

sub _reload {
  my $package = shift;

  unless($reloader) {
    RL('#reload')->warn("no reloader available\n ");
    $package->_init_reloader;
    if($reloader) {
      RL('#reload')->info("we reloaded ourselves");
      $package->_reload;
    }
    return;
  }
  # XXX 'no warnings' doesn't actually work

  # oh well.  If it's really a problem, let's grab stderr and filter it
  no warnings qw(redefine);
  local $SIG{__WARN__};
  $reloader->refresh;
  RL('#reload')->info('reloaded');
} # end subroutine _reload definition
########################################################################

sub release_number {
  my $package = shift;
  my $file = $package->data_dir . 'dotreader_release';
  (-e $file) or return('UNKNOWN');
  open(my $fh, '<', $file);
  # TODO make that a YAML file
  my $number = <$fh>;
  chomp($number);
  return($number);
} # end subroutine release_number definition
########################################################################

sub first_time {
  my $package = shift;
  my $file = $package->user_dir . 'first_time';
  if(-e $file) {
    warn "look at $file";
    return(unlink($file));
  }
  return(0);
} # end subroutine first_time definition
########################################################################

sub get_LICENSE {
  my $package = shift;
  return($package->_get_THIS('LICENSE'));
} # end subroutine get_LICENSE definition
########################################################################

sub get_COPYING {
  my $package = shift;
  return($package->_get_THIS('COPYING'));
} # end subroutine get_COPYING definition
########################################################################

sub _get_THIS {
  my $package = shift;
  my ($THIS) = @_;

  # TODO class data for caching
  my $file = $package->data_dir . $THIS;
  my $text;
  unless(-e $file) {
    if(-e $THIS) { # fallback to current directory
      $file = $THIS;
    }
    else {
      $text = <<"        ---";
        Your copy of this software appears to be without a $THIS file.
        This is against the terms of distribution.  Please report this
        infringement at http://dotreader.com/
        ---
      $text =~ s/^\s+//mg;
      return($text);
    }
  }
  open(my $fh, '<', $file) or die "failed to read $file $!";
  local $/;
  return(<$fh>);
} # end subroutine _get_THIS definition
########################################################################

# vi:ts=2:sw=2:et:sta
1;